forked from remittor/delphi-iocp-server-sample
-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathHPScktSrvr.pas
3113 lines (2754 loc) · 95.5 KB
/
HPScktSrvr.pas
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
unit HPScktSrvr;
{$DEFINE EXTLOG}
{!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
W_A_R_N_I_N_G !
-- Component THPServerSocketSPL provided ONLY AS EXAMPLE of using
"System Thread Pool" and NOT RECOMMENDED for practical use.
Use component THPServerSocket instead this.
-- Directive "USE_SLIST" enabled using SList functions. These functions
available only on Windows XP and higher versions. Do not define this
directive if You need to support Windows 2000.
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!}
(*******************************************************************************
Author: Sergey N. Naberegnyh
Version 1.4.0.7
Created: August, 05, 2008
Updated: July, 26, 2009
&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&
November, 22, 2008:
Not raised TCustomHPServerSocket.OnCreateAcceptor - Fixed
&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&
December, 03, 2008
- Included IPv6 support
- Restructuring unit
&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&
December, 04, 2008
- Support IPv6
- Adedded property "MinimumAcceptors"
&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&
January, 23, 2009
- Dynamic loading IPv6 functions for Win2k compatibility
&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&
January, 31, 2009
- AcceptEx failed if function TransmitFile
with DisconnectClient = TRUE return error
Fixed:
1) Added "closesocket" in
THPServerWorkThread.Execute: HPSO_TRANSMIT_DISCONNECT block.
2) In TAcceptThread.Execute "Break" operator replaced to "Continue"
- Fixed: Memory leaks if failed THPServerClient.Read, Write and Transmit
&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&
June, 30, 2009
- DecreaseWorkThreads routine changed
- OnAcceptorStart and OnAcceptorEnd events are added.
- TCustomHPServerClient.WaitConnectionData are added.
By default is "TRUE"
If this property is "FALSE" or "ConnBufSize" parameter in
"OnClientBeforeAccept" event handler equal to null, "OnClientConnect" event
raised as soon as connection arrives, without waiting for any data.
Otherwise "OnClientConnect" event raised only after data is received.
&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&
July, 26, 2009
- Fixed bug: client not removed from connections list
*******************************************************************************)
{$WARN SYMBOL_PLATFORM OFF}
{$DEFINE MINWINXP}
{$IFDEF MINWINXP}
{$DEFINE USE_SLIST}
{$ENDIF}
interface
uses
Windows, Classes, SysUtils, WinSock,
HPSockApi, CompletionPort,
uTempLog; // ÷òî áû áûë äîñòóï ê ïîòîêîâîé ïåðåìåííîé iCurrentThreadID è ÷òî áû ëîãèðîâàòü äåéñòâèÿ
const
MAX_WSA_BUFFERS = 32;
DefClientsCapacity = 4*1024; // 1024
DefStuctStackCapacity = 16*1024; // 4096
DefAcceptorsCount = 10;
DefMinAcceptors = 5;
DefThreadsPerProcessor = 4;
Addr_Buf_Len = SizeOf(TSockAddrIn) + 16;
resourcestring
sAcceptExNotFound = 'Function "AcceptEx" not found in current system.';
sGetAcceptExSockaddrsNotFound = 'Function "GetAcceptExSockaddrs" not found in current system.';
sClassInvalid = 'Invalid class of client';
type
TCustomHPServerClient = class;
THPServerClientSPL = class;
THPServerClient = class;
TCustomHPServerSocket = class;
THPServerSocketSPL = class;
TClientList = class;
THPSockOpCode = (HPSO_ACCEPT, HPSO_READ, HPSO_WRITE, HPSO_WRITE_ADV,
HPSO_TRANSMITFILE, HPSO_TRANSMIT_DISCONNECT,
HPSO_DISCONNECT, HPSO_USERASYNCCALL);
PHPSockIOStructSPL = ^THPSockIOStructSPL;
THPSockIOStructSPL = packed record
Ovp: TOverlapped;
CompletionKey: integer;
Error: integer;
OpCode: THPSockOpCode;
BuffersCount: integer;
Buffers: array [0..MAX_WSA_BUFFERS - 1] of TWsaBuf;
Client: THPServerClientSPL;
end;
PHPSockIOStruct = ^THPSockIOStruct;
THPSockIOStruct = packed record // 32 áàéòèêà
Ovp: TOverlapped;
OpCode: THPSockOpCode; // 20
Dummy1: Byte; // 21
Dummy2: Byte; // 22
Dummy3: Byte; // 23
CompletionKey: Integer; // 24
Client: THPServerClient; // 28
end;
TUserKeyRange = 16..MAXDWORD - 1;
EHPServerException = class(Exception);
THPServerThread = class(TThread)
private
FEvent: THandle;
procedure ClearClientsStack(const Stack: TClientList);
public
constructor Create(CreateSyspended: boolean);
destructor Destroy; override;
procedure Notify();
procedure Terminate();
function WaitForTimeout(TimeOut: cardinal): boolean;
end;
TCustomHPServerClient = class
private
FNext, FPrev: TCustomHPServerClient;
FList: TClientList;
FServer: TCustomHPServerSocket;
FASocket: TSocket;
FRefCount: integer; // ñ÷¸ò÷èê àêòèâíûõ ññûëîê íà ýòîãî êëèåíòà
FConnected: LongBool;
FPStruct: Pointer; // âðåìåííîå õðàíèëèùå óêàçàòåëåé íà ñòðóêòóðû (ñì. ôóíêöèþ ExchangeStruct)
FPStruct2: Pointer; // õðàíèëèùå äëÿ WSASend
FObjectID: Cardinal;
FClientID: Cardinal;
FLocalAddr: TSockAddrIn;
FRemoteAddr: TSockAddrIn;
FAddrOffset: integer;
FRecvBuf: PChar; // áóôåð äëÿ äàííûõ, ïîëó÷àåìûõ èç AcceptEx è WSARecv
FRecvBufSize: Integer;
FWaitConnectionData: boolean;
FAuthConnect: Boolean; // ïðèçíàê òîãî, ÷òî ïîëó÷èëè ïîñëå êîííåêòà êîððåêòíûé ïàêåò "ïðèâåòñòâèÿ"
function ExchangeStruct(P: Pointer): Pointer;
function ExchangeStruct2(P: Pointer): Pointer;
function ExtractSocket(): TSocket;
function GetLocalAddress: string;
function GetLocalHost: string;
function GetLocalPort: Integer;
function GetRemoteAddr: TSockAddrIn;
function GetRemoteAddress: string;
function GetRemoteHost: string;
function GetRemotePort: Integer;
procedure ExtractAddresses(ChangeAddr: Boolean = False);
function GetConnectionTime: Cardinal;
procedure ReallocConnBuf(NewSize: integer);
function GetLocalAddr: TSockAddrIn;
function GetRecvBufSize: Integer;
procedure SetWaitConnectionData(const Value: boolean);
protected
function _AddRef: integer;
function _Release: integer;
public
constructor Create; virtual;
destructor Destroy; override;
procedure Disconnect(Reason: Integer = 0); virtual; abstract;
property ObjectID: Cardinal read FObjectID;
property ClientID: Cardinal read FClientID;
property LocalHost: string read GetLocalHost;
property LocalAddress: string read GetLocalAddress;
property LocalPort: Integer read GetLocalPort;
property LocalAddr: TSockAddrIn read GetLocalAddr;
property RemoteHost: string read GetRemoteHost;
property RemoteAddress: string read GetRemoteAddress;
property RemotePort: Integer read GetRemotePort;
property RemoteAddr: TSockAddrIn read GetRemoteAddr;
property ASocket: TSocket read FASocket; // sAcceptSocket
property Server: TCustomHPServerSocket read FServer;
property Connected: LongBool read FConnected;
property AuthConnect: Boolean read FAuthConnect write FAuthConnect;
property RecvBuf: PChar read FRecvBuf;
property RecvBufSize: Integer read FRecvBufSize; // GetRecvBufSize;
property ConnectionTime: Cardinal read GetConnectionTime;
{### 1.4.0.6 Added june, 30, 2009}
property WaitConnectionData: boolean read FWaitConnectionData write SetWaitConnectionData;
{### /1.4.0.6}
end;
THPServerClientSPL = class(TCustomHPServerClient)
public
procedure Disconnect(Reason: Integer = 0); override;
function ReadBuffer(const Buffers: TWsaBuf; BufCount: integer; CompletionKey: integer): Cardinal;
function WriteBuffer(const Buffers: TWsaBuf; BufCount: integer; CompletionKey: integer): Cardinal;
end;
THPServerClient = class(TCustomHPServerClient)
public
procedure Disconnect(Reason: Integer = 0); override;
function ReadBufferEx(var Buffers: TWsaBuf; BufCount, CompletionKey: Integer; DMode: Integer; var AValue: Integer): Integer;
function ReadBuffer(var Buffers: TWsaBuf; BufCount: integer; CompletionKey: integer): integer;
function WriteBuffer(var Buffers: TWsaBuf; BufCount: integer; CompletionKey: integer): integer;
function WriteBuffer2(var Buffers: TWsaBuf; BufCount: integer; CompletionKey: integer): integer;
function Transmit(hFile: THandle; BytesToWrite, BytesPerSend: DWORD;
pTransmitBuffers: PTransmitFileBuffers;
CompletionKey: integer; DisconnectClient: boolean): integer;
end;
THPServerClientSPLClass = class of THPServerClientSPL;
THPServerClientClass = class of THPServerClient;
TThreadSafeStack = class
private
FCS: TRTLCriticalSection;
FSpinCount: Cardinal;
FClosed: integer;
function GetClosed: boolean;
procedure SetClosed(const Value: boolean);
procedure SetSpinCount(const Value: Cardinal);
protected
FCount: integer;
FCapacity: integer;
procedure SetCapacity(const Value: integer); virtual; abstract;
public
constructor Create(ACapacity: integer);
destructor Destroy; override;
procedure Lock;
procedure Unlock;
procedure Clear; virtual; abstract;
property Capacity: integer read FCapacity write SetCapacity;
property Count: integer read FCount;
property Closed: boolean read GetClosed write SetClosed;
property SpinCount: Cardinal read FSpinCount write SetSpinCount;
end;
TSocketStack = class(TThreadSafeStack)
private
FSockets: array [0..$4080] of TSocket;
protected
procedure SetCapacity(const Value: integer); override;
public
function Push(ASocket: TSocket): boolean;
function Pop(out ASocket: TSocket): boolean;
procedure Clear; override;
end;
{$IFDEF USE_SLIST}
{
PHPSListEntry = ^THPSListEntry;
THPSListEntry = record
case byte of
0: (Next: Pointer);
1: (IOStruct: THPSockIOStruct);
end;
PHPSListEntrySPL = ^THPSListEntrySPL;
THPSListEntrySPL = record
case byte of
0: (Next: Pointer);
1: (IOStruct: THPSockIOStructSPL);
end;
}
TStructStack = class(TObject)
private
FSList: TSListHeader;
FItemSize: integer;
FCapacity: integer;
FTotalCount: Integer;
FClosed: boolean;
protected
procedure SetCapacity(const Value: integer);
function GetCount: integer;
public
constructor Create(ACapacity: integer; ItemSize: integer);
destructor Destroy; override;
procedure Push(PStruct: Pointer);
function Pop: Pointer;
procedure Clear;
property Capacity: integer read FCapacity write SetCapacity;
property Closed: boolean read FClosed write FClosed;
property Count: integer read GetCount;
property TotalCount: Integer read FTotalCount;
end;
{$ELSE}
PHPStructArray = ^THPStructArray;
THPStructArray = array[0..MAXWORD] of Pointer;
TStructStack = class(TThreadSafeStack)
private
FList: PHPStructArray;
FItemSize: integer;
protected
procedure SetCapacity(const Value: integer); override;
public
constructor Create(ACapacity: integer; ItemSize: integer);
destructor Destroy; override;
procedure Push(PStruct: Pointer);
function Pop: Pointer;
procedure Clear; override;
end;
{$ENDIF}
TEnumClients = function(AClient: TCustomHPServerClient): boolean of object;
TClientList = class(TThreadSafeStack)
private
FClient: TCustomHPServerClient;
FNextEnum: TCustomHPServerClient;
FCountMax: Integer;
FCountMaxTime: TDateTime;
protected
procedure SetCapacity(const Value: integer); override;
public
constructor Create(ACapacity: Integer);
procedure Push(AClient: TCustomHPServerClient);
function Pop: TCustomHPServerClient;
function Remove(AClient: TCustomHPServerClient): integer;
procedure Clear; override;
procedure Enum(const EnumProc: TEnumClients);
property CountMax: Integer read FCountMax;
property CountMaxTime: TDateTime read FCountMaxTime;
end;
THPThreadList = class(TObject)
private
FList: TList;
FCS: TRTLCriticalSection;
public
constructor Create;
destructor Destroy; override;
procedure Add(Item: Pointer);
function LockList: TList;
function Remove(Item: Pointer): boolean;
procedure UnlockList;
end;
THPServConnectEvent = procedure(AClient: TCustomHPServerClient; ConnectionData: PChar; ConnectionDataLen: Integer) of object;
THPServBeforeAcceptEvent = procedure(AClient: TCustomHPServerClient; var ConnBufSize: Integer) of object;
THPServDisconnectEvent = procedure(AClient: TCustomHPServerClient) of object;
THPServFinalizeRef1Event = procedure(AClient: TCustomHPServerClient) of object;
THPServCompleteEvent = procedure(AClient: TCustomHPServerClient; BytesTransfered: Cardinal; CompletionKey: Integer; Error: Integer) of object;
THPInitSocketEvent = procedure(Sender: TCustomHPServerSocket; Socket: TSocket) of object;
THPLogMessageEvent = procedure(const Params: array of PAnsiChar; EventType, Category: Word; ID: DWORD) of object;
THPLogMsgEvent = procedure(ModuleID, LogLevel: Byte; ThreadID, ClientID: Cardinal; const Line: String) of object;
THPExceptionEvent = procedure(Client: TCustomHPServerClient; const Message: string; const ExceptClass: string; ExceptAddress: pointer) of object;
THPServUserAsyncCall = procedure(Sender: TCustomHPServerSocket; UserKey: Cardinal; pUserData: pointer) of object;
THPUserDeviceEvent = procedure(Sender: TCustomHPServerSocket; Success: boolean; BytesTransfered: Cardinal; CompletionKey: Cardinal; pOvp: POverlapped) of object;
TAcceptorPriority = (apLow, apNormal, apHigh);
TBindAddr = record
SockFamily: integer;
SockType: integer;
AddrLen: integer;
Addr: TSockAddrIn;
end;
TCustomHPServerSocket = class({$IFDEF WITH_GUI}TComponent{$ELSE}TObject{$ENDIF})
private
FBindAddr: TBindAddr;
FClientClass: THPServerClientClass; // THPServerClientSPLClass; // ???? ïî÷åìó âäðóã SPL ????
FAcceptorsCount: integer;
FMinAcceptors: integer;
FActualAcceptors: integer;
FAcceptThread: THPServerThread;
FAcceptorPriority: TAcceptorPriority;
FClientObjectsCount: integer;
FConnections: TClientList;
FClientStack: TClientList;
FStructStack: TStructStack; // ñòåê îñíîâíûõ ñòðóêòóð äëÿ AcceptEx, WSARecv è ò.ä.
FStructStack2: TStructStack; // ñòåê ñòðóêòóð äëÿ ôóíêöèè WSASend
FActive: LongBool;
FServiceOrPort: string;
FAddress: string;
FClientsEvent: THandle;
FAcceptEx: TAcceptEx;
FDisconnectEx: TDisconnectEx;
FGetAcceptExSockaddrs: TGetAcceptExSockaddrs;
FTransmitFile: TTransmitFile;
FOnCreateListener: THPInitSocketEvent;
FOnCreateAcceptor: THPInitSocketEvent;
FOnReadComplete: THPServCompleteEvent;
FOnWriteComplete: THPServCompleteEvent;
FOnWriteComplete2: THPServCompleteEvent;
FOnClientConnect: THPServConnectEvent;
FOnClientDisconnect: THPServDisconnectEvent;
FOnClientFinalizeRef1: THPServFinalizeRef1Event;
FOnLogMessage: THPLogMessageEvent;
FOnLogMsg: THPLogMsgEvent;
FOnThreadException: THPExceptionEvent;
FOnClientBeforeAccept: THPServBeforeAcceptEvent;
FFullExtensionsSupport: boolean;
FChangeRemoteLocalAddr: Boolean;
FBindSocketToIocpAfterAccept: Boolean;
procedure GetExtensions;
procedure IncreazeClients;
procedure DecreazeClients;
function CloseConnectionsProc(AClient: TCustomHPServerClient): boolean;
function GetClientsCapacity: integer;
function GetStuctCapacity: integer;
function GetStuct2Capacity: integer;
procedure SetStuctCapacity(const Value: integer);
procedure SetStuct2Capacity(const Value: integer);
procedure SetClientsCapacity(const Value: integer);
procedure SetAcceptorsCount(const Value: integer);
procedure SetOnClientConnect(const Value: THPServConnectEvent);
procedure SetOnClientDisconnect(const Value: THPServDisconnectEvent);
procedure SetOnClientFinalizeRef1(const Value: THPServFinalizeRef1Event);
procedure SetOnCreateAcceptor(const Value: THPInitSocketEvent);
procedure SetOnCreateListener(const Value: THPInitSocketEvent);
procedure SetOnReadComplete(const Value: THPServCompleteEvent);
procedure SetOnWriteComplete(const Value: THPServCompleteEvent);
procedure SetOnWriteComplete2(const Value: THPServCompleteEvent);
procedure SetAddress(const Value: string);
procedure SetServiceOrPort(const Value: string);
procedure SetOnLogMessage(const Value: THPLogMessageEvent);
procedure SetOnLogMsg(const Value: THPLogMsgEvent);
procedure SetOnThreadException(const Value: THPExceptionEvent);
procedure SetOnClientBeforeAccept(const Value: THPServBeforeAcceptEvent);
procedure SetAcceptorPriority(const Value: TAcceptorPriority);
function GetConnectionsCount: integer;
function GetClientStackCount: integer;
function GetStructStackCount: integer;
function GetStructStack2Count: integer;
procedure SetMinAcceptors(Value: integer);
procedure ClientAccepted;
public
FListener: TSocket; // sListenSocket
constructor Create{$IFDEF WITH_GUI}(AOwner: TComponent){$ENDIF};
destructor Destroy; override;
procedure Open; virtual;
procedure Close(Timeout: Cardinal); virtual; abstract;
procedure EnumerateConnections(const Proc: TEnumClients);
procedure LogMessage(const Params: array of PAnsiChar; EventType, Category: Word; ID: DWORD);
procedure LogMsg(ModuleID, LogLevel: Byte; ClientID: Cardinal; const Line: String);
procedure LogMsgXTC(ModuleID, LogLevel: Byte; ClientID: Cardinal; const Line: String);
procedure LogMsgXT(ModuleID, LogLevel: Byte; const Line: String);
procedure LogMsgXS(ModuleID, LogLevel: Byte; const Line: String);
function GetConnectionsCountEx(var CountMax: Integer; var CountMaxTime: TDateTime): Integer;
property Active: LongBool read FActive;
property ConnectionsCount: integer read GetConnectionsCount;
property ClientStackCount: integer read GetClientStackCount;
property ClientObjectsCount: integer read FClientObjectsCount;
property StructStackCount: integer read GetStructStackCount;
property StructStack2Count: integer read GetStructStack2Count;
property LSocket: TSocket read FListener;
property Address: string read FAddress write SetAddress;
property ServiceOrPort: string read FServiceOrPort write SetServiceOrPort;
property Port: string read FServiceOrPort write SetServiceOrPort;
property ClientStackCapacity: integer read GetClientsCapacity write SetClientsCapacity default DefClientsCapacity;
property StuctStackCapacity: integer read GetStuctCapacity write SetStuctCapacity default DefStuctStackCapacity;
property StuctStack2Capacity: integer read GetStuct2Capacity write SetStuct2Capacity default DefStuctStackCapacity;
property AcceptorsCount: integer read FAcceptorsCount write SetAcceptorsCount default DefAcceptorsCount;
property MinimumAcceptors: integer read FMinAcceptors write SetMinAcceptors default DefMinAcceptors;
property AcceptorPriority: TAcceptorPriority read FAcceptorPriority write SetAcceptorPriority default apNormal;
property FullExtensionsSupport: boolean read FFullExtensionsSupport;
property ChangeRemoteLocalAddr: Boolean read FChangeRemoteLocalAddr write FChangeRemoteLocalAddr;
property BindSocketToIocpAfterAccept: Boolean read FBindSocketToIocpAfterAccept write FBindSocketToIocpAfterAccept;
property OnCreateListener: THPInitSocketEvent read FOnCreateListener write SetOnCreateListener;
property OnCreateAcceptor: THPInitSocketEvent read FOnCreateAcceptor write SetOnCreateAcceptor;
property OnClientBeforeAccept: THPServBeforeAcceptEvent read FOnClientBeforeAccept write SetOnClientBeforeAccept;
property OnClientConnect: THPServConnectEvent read FOnClientConnect write SetOnClientConnect;
property OnClientDisconnect: THPServDisconnectEvent read FOnClientDisconnect write SetOnClientDisconnect;
property OnClientFinalizeRef1: THPServFinalizeRef1Event read FOnClientFinalizeRef1 write SetOnClientFinalizeRef1;
property OnReadComplete: THPServCompleteEvent read FOnReadComplete write SetOnReadComplete;
property OnWriteComplete: THPServCompleteEvent read FOnWriteComplete write SetOnWriteComplete;
property OnWriteComplete2: THPServCompleteEvent read FOnWriteComplete2 write SetOnWriteComplete2;
property OnLogMessage: THPLogMessageEvent read FOnLogMessage write SetOnLogMessage;
property OnLogMsg: THPLogMsgEvent read FOnLogMsg write SetOnLogMsg;
property OnThreadException: THPExceptionEvent read FOnThreadException write SetOnThreadException;
end;
THPServerSocketSPL = class(TCustomHPServerSocket)
private
FClientClass: THPServerClientSPLClass;
function CloseConnectionsProc(AClient: TCustomHPServerClient): boolean;
procedure SetClientClass(const Value: THPServerClientSPLClass);
public
constructor Create{$IFDEF WITH_GUI}(AOwner: TComponent){$ENDIF};
destructor Destroy; override;
procedure Open; override;
procedure Close(Timeout: Cardinal); override;
property ClientClass: THPServerClientSPLClass read FClientClass write SetClientClass;
published
property Address;
property ServiceOrPort;
property ClientStackCapacity;
property StuctStackCapacity;
property AcceptorsCount;
property MinimumAcceptors;
property AcceptorPriority;
property OnCreateListener;
property OnCreateAcceptor;
property OnClientBeforeAccept;
property OnClientConnect;
property OnClientDisconnect;
property OnReadComplete;
property OnWriteComplete;
property OnWriteComplete2;
property OnLogMessage;
property OnLogMsg;
property OnThreadException;
end;
THPServerSocket = class(TCustomHPServerSocket)
private
FClientClass: THPServerClientClass;
FPort: TCompletionPort;
FWorkThreads: integer;
{### 1.4.0.6 Added june, 30, 2009}
FDecreaseTryCount: integer;
FDecreaseCompleteEvent: THandle;
{### /1.4.0.6}
FActiveThreads: integer;
FMinWorkThreads: integer;
FThreadsList: THPThreadList;
FOnUserAsyncCall: THPServUserAsyncCall;
FOnThreadEnd: TNotifyEvent;
FOnThreadStart: TNotifyEvent;
{### 1.4.0.6 Added june, 30, 2009}
FOnAcceptorEnd: TNotifyEvent;
FOnAcceptorStart: TNotifyEvent;
{### /1.4.0.6}
FDecreaseLock: integer;
FOnDeviceCompletion: THPUserDeviceEvent;
function CloseConnectionsProc(AClient: TCustomHPServerClient): boolean;
procedure SetClientClass(const Value: THPServerClientClass);
procedure SetMinWorkThreads(const Value: integer);
procedure SetOnUserAsyncCall(const Value: THPServUserAsyncCall);
procedure SetOnThreadEnd(const Value: TNotifyEvent);
procedure SetOnThreadStart(const Value: TNotifyEvent);
procedure SetOnDeviceCompletion(const Value: THPUserDeviceEvent);
procedure SetOnAcceptorEnd(const Value: TNotifyEvent);
procedure SetOnAcceptorStart(const Value: TNotifyEvent);
public
constructor Create{$IFDEF WITH_GUI}(AOwner: TComponent){$ENDIF};
destructor Destroy; override;
procedure Open; override;
procedure Close(Timeout: Cardinal); override;
procedure AddWorkThread;
function DecreaseWorkThreads: boolean;
function UserAsyncCall(UserKey: Cardinal; PUserData: Pointer): boolean;
function BindUserDevice(hDevice: THandle; CompletionKey: TUserKeyRange): boolean;
property ClientClass: THPServerClientClass read FClientClass write SetClientClass;
property WorkThreads: integer read FWorkThreads;
property ActiveThreads: integer read FActiveThreads;
published
property MinimumWorkThreads: integer read FMinWorkThreads write SetMinWorkThreads;
property Address;
property ServiceOrPort;
property ClientStackCapacity;
property StuctStackCapacity;
property StuctStack2Capacity;
property AcceptorsCount;
property MinimumAcceptors;
property AcceptorPriority;
property OnCreateListener;
property OnCreateAcceptor;
property OnClientBeforeAccept;
property OnClientConnect;
property OnClientDisconnect;
property OnClientFinalizeRef1;
property OnReadComplete;
property OnWriteComplete;
property OnWriteComplete2;
property OnLogMessage;
property OnLogMsg;
property OnThreadException;
property OnUserAsyncCall: THPServUserAsyncCall read FOnUserAsyncCall write SetOnUserAsyncCall;
property OnUserDeviceCompletion: THPUserDeviceEvent read FOnDeviceCompletion write SetOnDeviceCompletion;
property OnThreadStart: TNotifyEvent read FOnThreadStart write SetOnThreadStart;
property OnThreadEnd: TNotifyEvent read FOnThreadEnd write SetOnThreadEnd;
{### 1.4.0.6 Added june, 30, 2009}
property OnAcceptorStart: TNotifyEvent read FOnAcceptorStart write SetOnAcceptorStart;
property OnAcceptorEnd: TNotifyEvent read FOnAcceptorEnd write SetOnAcceptorEnd;
{### /1.4.0.6}
end;
{$IFDEF WITH_GUI}
procedure Register;
{$ENDIF}
var
GlobObjectIDs: Cardinal = 0;
GlobClientIDs: Cardinal = 0;
implementation
{$IFDEF WITH_GUI}
procedure Register;
begin
RegisterComponents('Internet', [THPServerSocket{, THPServerSocketSPL}]);
end;
{$ENDIF}
{$IFNDEF MINWINXP}
{$IFDEF USE_SLIST}
var
SListFunc: TSListFunc = ();
{$ENDIF}
{$ENDIF}
var
ThreadClientList: TList = nil; // èñïîëüçóåòñÿ ïðè ëîãèðîâàíèè (äîï. èíôà)
const
CP_TERMINATE = 0;
CP_IO = 1;
CP_DELETETHREAD = 2;
CP_USERASYNCCALL = 3;
type
TAcceptThreadSPL = class(THPServerThread)
private
FServer: THPServerSocketSPL;
protected
procedure Execute; override;
public
constructor Create(Server: THPServerSocketSPL; CreateSyspended: boolean);
end;
TAcceptThread = class(THPServerThread)
private
FServer: THPServerSocket;
protected
procedure Execute; override;
public
constructor Create(Server: THPServerSocket; CreateSyspended: boolean);
end;
THPServerWorkThread = class(TThread)
private
FServer: THPServerSocket;
protected
procedure Execute; override;
public
constructor Create(Server: THPServerSocket; CreateSyspended: boolean);
function WaitForTimeout(TimeOut: cardinal): boolean;
end;
{ TThreadSafeStack }
constructor TThreadSafeStack.Create(ACapacity: integer);
begin
InitializeCriticalSectionAndSpinCount(FCS, 128 or CS_Alloc_Event);
Capacity := ACapacity;
FCount := 0;
end;
destructor TThreadSafeStack.Destroy;
begin
Clear;
DeleteCriticalSection(FCS);
inherited;
end;
function TThreadSafeStack.GetClosed: boolean;
begin
Result := FClosed <> 0;
end;
procedure TThreadSafeStack.Lock;
begin
EnterCriticalSection(FCS);
end;
procedure TThreadSafeStack.SetClosed(const Value: boolean);
var
I: integer;
begin
if Value then I := 1 else I := 0;
InterlockedExchange(FClosed, I);
end;
procedure TThreadSafeStack.SetSpinCount(const Value: Cardinal);
begin
SetCriticalSectionSpinCount(FCS, Value);
FSpinCount := Value;
end;
procedure TThreadSafeStack.Unlock;
begin
LeaveCriticalSection(FCS);
end;
{ TSocketStack }
procedure TSocketStack.Clear;
var
n: integer;
begin
Lock;
try
for n := 0 to Pred(FCount) do closesocket(FSockets[n]);
FCount := 0;
finally
Unlock;
end;
end;
function TSocketStack.Pop(out ASocket: TSocket): boolean;
begin
Lock;
try
Result := FCount > 0;
if Result then begin
Dec(FCount);
ASocket := FSockets[FCount];
end;
finally
Unlock;
end;
end;
function TSocketStack.Push(ASocket: TSocket): boolean;
begin
Lock;
try
Result := (FClosed = 0) and (FCount < FCapacity);
if Result then begin
FSockets[FCount] := ASocket;
Inc(FCount);
end;
finally
Unlock;
end;
end;
procedure TSocketStack.SetCapacity(const Value: integer);
begin
if (Value < 0) or (Value > SizeOf(FSockets)) then raise EHPServerException.Create('Invalid capacity value');
InterlockedExchange(FCapacity, Value);
end;
{ TCustomHPServerSocket }
constructor TCustomHPServerSocket.Create{$IFDEF WITH_GUI}(AOwner: TComponent){$ENDIF};
begin
inherited;
FAcceptorPriority := apNormal;
FClientClass := THPServerClient; // THPServerClientSPL;
// FClientStack - ãëîáàëüíûé ñïèñîê êëèåíòñêèõ îáúåêòîâ, êîòîðûå ìîæíî ïîâòîðíî èñïîëüçîâàòü
FClientStack := TClientList.Create(DefClientsCapacity);
// FConnections - ýòî ñïèñêîê ïðèêîííåê÷åííûõ êëèåíòîâ, êîòîðûå âçÿòû èç ñïèñêà FClientStack
FConnections := TClientList.Create(-1);
FAcceptorsCount := DefAcceptorsCount;
FMinAcceptors := DefMinAcceptors;
FBindSocketToIocpAfterAccept := False;
FClientsEvent := CreateEvent(nil, true, true, nil);
if FClientsEvent = 0 then raise EHPServerException.Create(SysErrorMessage(GetLastError));
end;
destructor TCustomHPServerSocket.Destroy;
begin
Close(INFINITE);
FConnections.Free;
FClientStack.Free;
CloseHandle(FClientsEvent);
inherited;
end;
function TCustomHPServerSocket.GetClientsCapacity: integer;
begin
Result := FClientStack.Capacity;
end;
procedure TCustomHPServerSocket.GetExtensions;
var
hWS32: THandle;
begin
hWS32 := GetModuleHandle('wsock32.dll');
@FAcceptEx := GetExtensionFunc(FListener, WSAID_ACCEPTEX);
if not Assigned(FAcceptEx) then begin
@FAcceptEx := GetProcAddress(hWS32, 'AcceptEx');
if not Assigned(FAcceptEx) then raise EHPServerException.Create(sAcceptExNotFound);
end;
@FGetAcceptExSockaddrs := GetExtensionFunc(FListener, WSAID_GETACCEPTEXSOCKADDRS);
if not Assigned(FGetAcceptExSockaddrs) then begin
@FGetAcceptExSockaddrs := GetProcAddress(hWS32, 'GetAcceptExSockaddrs');
if not Assigned(FGetAcceptExSockaddrs) then raise EHPServerException.Create(sGetAcceptExSockaddrsNotFound);
end;
@FTransmitFile := GetExtensionFunc(FListener, WSAID_TRANSMITFILE);
@FDisconnectEx := GetExtensionFunc(FListener, WSAID_DISCONNECTEX);
FFullExtensionsSupport := Assigned(FTransmitFile) and Assigned(FDisconnectEx);
end;
function TCustomHPServerSocket.GetStuctCapacity: integer;
begin
Result := FStructStack.Capacity;
end;
procedure TCustomHPServerSocket.SetStuctCapacity(const Value: integer);
begin
FStructStack.Capacity := Value;
end;
function TCustomHPServerSocket.GetStuct2Capacity: integer;
begin
Result := FStructStack2.Capacity;
end;
procedure TCustomHPServerSocket.SetStuct2Capacity(const Value: integer);
begin
FStructStack2.Capacity := Value;
end;
procedure TCustomHPServerSocket.SetClientsCapacity(const Value: integer);
begin
FClientStack.Capacity := Value;
end;
procedure TCustomHPServerSocket.SetAcceptorsCount(const Value: integer);
var
Old: integer;
begin
if Value > 0 then begin
Old := InterlockedExchange(FAcceptorsCount, Value);
if (Old < Value) and Assigned(FAcceptThread) then FAcceptThread.Notify;
end;
end;
procedure TCustomHPServerSocket.SetOnClientConnect(const Value: THPServConnectEvent);
begin
if not FActive then FOnClientConnect := Value;
end;
procedure TCustomHPServerSocket.SetOnClientDisconnect(const Value: THPServDisconnectEvent);
begin
if not FActive then FOnClientDisconnect := Value;
end;
procedure TCustomHPServerSocket.SetOnClientFinalizeRef1(const Value: THPServFinalizeRef1Event);
begin
if not FActive then FOnClientFinalizeRef1 := Value;
end;
procedure TCustomHPServerSocket.SetOnCreateAcceptor(const Value: THPInitSocketEvent);
begin
if not FActive then FOnCreateAcceptor := Value;
end;
procedure TCustomHPServerSocket.SetOnCreateListener(const Value: THPInitSocketEvent);
begin
if not FActive then FOnCreateListener := Value;
end;
procedure TCustomHPServerSocket.SetOnReadComplete(const Value: THPServCompleteEvent);
begin
if not FActive then FOnReadComplete := Value;
end;
procedure TCustomHPServerSocket.SetOnWriteComplete(const Value: THPServCompleteEvent);
begin
if not FActive then FOnWriteComplete := Value;
end;
procedure TCustomHPServerSocket.SetOnWriteComplete2(const Value: THPServCompleteEvent);
begin
if not FActive then FOnWriteComplete2 := Value;
end;
procedure TCustomHPServerSocket.SetAddress(const Value: string);
begin
if not FActive then FAddress := Value;
end;
procedure TCustomHPServerSocket.SetServiceOrPort(const Value: string);
begin
if not FActive then FServiceOrPort := Value;
end;
function TCustomHPServerSocket.CloseConnectionsProc(AClient: TCustomHPServerClient): boolean;
begin
Result := true;
AClient.Disconnect;
end;
procedure TCustomHPServerSocket.DecreazeClients;
begin
if InterlockedDecrement(FClientObjectsCount) = 0 then SetEvent(FClientsEvent);
end;
procedure TCustomHPServerSocket.IncreazeClients;
begin
if InterlockedIncrement(FClientObjectsCount) = 1 then ResetEvent(FClientsEvent);
end;
procedure TCustomHPServerSocket.SetOnLogMessage(const Value: THPLogMessageEvent);
begin
if not FActive then FOnLogMessage := Value;
end;
procedure TCustomHPServerSocket.LogMessage(const Params: array of PAnsiChar; EventType, Category: Word; ID: DWORD);
begin
if Assigned(OnLogMessage) then OnLogMessage(Params, EventType, Category, ID);
end;
procedure TCustomHPServerSocket.SetOnLogMsg(const Value: THPLogMsgEvent);
begin
if not FActive then FOnLogMsg := Value;
end;
procedure TCustomHPServerSocket.LogMsg(ModuleID, LogLevel: Byte; ClientID: Cardinal; const Line: String);
var
aThreadID: Cardinal;
begin
if Assigned(OnLogMsg) then begin
aThreadID := GetCurrentThreadNumber($FFFFFFFE);
OnLogMsg(ModuleID, LogLevel, aThreadID, ClientID, Line);
end;
end;
procedure TCustomHPServerSocket.LogMsgXTC(ModuleID, LogLevel: Byte; ClientID: Cardinal; const Line: String);
begin
LogMsg(ModuleID, LogLevel, ClientID, Line);
end;
procedure TCustomHPServerSocket.LogMsgXT(ModuleID, LogLevel: Byte; const Line: String);
begin
LogMsg(ModuleID, LogLevel, $FFFFFFFF, Line);
end;
procedure TCustomHPServerSocket.LogMsgXS(ModuleID, LogLevel: Byte; const Line: String);
begin
if Assigned(OnLogMsg) then OnLogMsg(ModuleID, LogLevel, $FFFFFFFF, $FFFFFFFF, Line);
end;
procedure TCustomHPServerSocket.SetOnThreadException(const Value: THPExceptionEvent);
begin
if not FActive then FOnThreadException := Value;
end;
procedure TCustomHPServerSocket.SetOnClientBeforeAccept(const Value: THPServBeforeAcceptEvent);
begin
if not FActive then FOnClientBeforeAccept := Value;
end;
procedure TCustomHPServerSocket.Open;
var
WD: WSAData;
BindAddrInfo, P: PAddrInfo;
n: integer;
begin
IsMultiThread := true;
if SOCKET_ERROR = WSAStartup(MakeWord(2, 2), WD) then
raise EHPServerException.Create(SysErrorMessage(WSAGetLastError));
FClientStack.Closed := false;
FConnections.Closed := false;