build.gradle

plugins {
    id 'jacoco'
    id 'groovy'
    id 'java-library'
    id 'maven-publish'
    id 'org.jetbrains.dokka' version '1.4.0-rc'
    id 'org.jetbrains.kotlin.jvm' version '1.4.0'
    id 'org.unbroken-dome.test-sets' version '3.0.1'
    id "com.github.ben-manes.versions" version "0.29.0"
}

group projectGroupId
version projectVersion

java {
    sourceCompatibility = JavaVersion.VERSION_1_8
    targetCompatibility = JavaVersion.VERSION_1_8
}


ext {
    processorApiVersion = '1.1.0'
    jacksonVersion = '2.11.2'

    bintrayUser = project.findProperty ('BINTRAY_USER') ?: System.getenv ("BINTRAY_USER") ?: 'n/a'
    bintrayKey =  project.findProperty ('BINTRAY_KEY') ?: System.getenv ("BINTRAY_KEY") ?: 'n/a'
}


repositories {
    mavenCentral()
    jcenter()
    maven {
        url "https://oss.sonatype.org/content/repositories/snapshots"
    }

    maven {
        url "https://dl.bintray.com/openapi-processor/primary"
        content {
           includeGroup "io.openapiprocessor"
        }
        mavenContent {
            releasesOnly()
        }
    }

    maven {
        url "https://oss.jfrog.org/artifactory/oss-snapshot-local"
        content {
           includeGroup "io.openapiprocessor"
        }
        mavenContent {
            snapshotsOnly()
        }
    }
}

tasks.withType(Test) {
    useJUnitPlatform()
}

testSets {
    testInt
}

check.dependsOn testInt


compileGroovy {
    dependsOn 'compileKotlin'
    classpath += files(compileKotlin.destinationDir)
}

compileTestGroovy {
    dependsOn 'compileKotlin'
    classpath += files(compileKotlin.destinationDir)
    classpath += files(compileTestKotlin.destinationDir)
}

compileKotlin {
    kotlinOptions.jvmTarget = "1.8"
}

compileTestKotlin {
    kotlinOptions.jvmTarget = "1.8"
}

dependencies {
    components.all(JacksonPlatformRule)
    components.all(KotlinPlatformRule)

    implementation 'org.codehaus.groovy:groovy:2.5.12'
    implementation 'org.codehaus.groovy:groovy-nio:2.5.12'
    implementation "com.fasterxml.jackson.module:jackson-module-kotlin:$jacksonVersion"

    compileOnly "io.openapiprocessor:openapi-processor-api:$processorApiVersion"

    implementation 'org.openapi4j:openapi-parser:1.0.3'
    implementation ('io.swagger.parser.v3:swagger-parser:2.0.21') {
        exclude group: 'io.swagger.parser.v3', module: 'swagger-parser-v2-converter'
        exclude group: 'io.swagger.core.v3', module: 'swagger-annotations'
    }

     implementation ('com.google.googlejavaformat:google-java-format:1.8') {
        exclude group: 'com.google.guava'
    }

    implementation ('com.google.guava:guava:29.0-jre') {
        exclude group: 'com.google.guava'
        exclude group: 'com.google.j2objc'
        exclude group: 'com.google.code.findbugs'
        exclude group: 'com.google.errorprone'
        exclude group: 'org.checkerframework'
        exclude group: 'org.codehaus.mojo'
    }

    testImplementation "io.openapiprocessor:openapi-processor-api:$processorApiVersion"
    testImplementation ('io.openapiprocessor:openapi-processor-test:1.0.1') {
        exclude group: 'com.google.guava'
    }

    testImplementation("com.google.jimfs:jimfs:1.1") {
         exclude group: 'com.google.guava'
     }

    testImplementation ("org.junit.jupiter:junit-jupiter-api:5.6.2")
    testCompileOnly  ("junit:junit:4.13")
    testRuntimeOnly ("org.junit.jupiter:junit-jupiter-engine:5.6.2")
    testRuntimeOnly ("org.junit.vintage:junit-vintage-engine:5.6.2")

    testImplementation ('org.spockframework:spock-core:2.0-M3-groovy-2.5') {
        exclude group: 'org.codehaus.groovy'
        exclude group: 'junit'
    }
    testImplementation ('org.spockframework:spock-junit4:2.0-M3-groovy-2.5') {
        exclude group: 'org.codehaus.groovy'
        exclude group: 'junit'
    }
    testImplementation("io.mockk:mockk:1.10.0")
    testImplementation("io.kotest:kotest-runner-junit5:4.2.0")
    testImplementation 'net.bytebuddy:byte-buddy:1.10.11'
    testImplementation 'ch.qos.logback:logback-classic:1.2.3'
}

tasks.withType(Test) {
    finalizedBy jacocoTestReport
}


jacoco {
    toolVersion = "0.8.5"
}

project.jacocoTestReport {
    getExecutionData().setFrom(fileTree(buildDir).include("/jacoco/*.exec"))
}


task sourcesJar(type: Jar, dependsOn: classes) {
    archiveClassifier.set ('sources')
    from sourceSets.main.allSource
}

task javadocJar(type: Jar, dependsOn: [groovydoc, dokkaHtml]) {
    archiveClassifier.set ('javadoc')
    from "$buildDir/docs"
}

artifacts {
    archives sourcesJar
    archives javadocJar
}

groovydoc {
    destinationDir file("$buildDir/docs/groovy")
}

dokkaHtml {
    outputDirectory = "$buildDir/docs/kotlin"
}

apply from: "${rootProject.rootDir}/gradle/publishing.gradle"
apply from: "${rootProject.rootDir}/gradle/publishing.tasks.gradle.kts"