forked from heterodb/pg-strom
-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathcuda_gpuscan.cu
1105 lines (1023 loc) · 30.6 KB
/
cuda_gpuscan.cu
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
/*
* cuda_gpuscan.cu
*
* Device implementation of GpuScan
* ----
* Copyright 2011-2023 (C) KaiGai Kohei <[email protected]>
* Copyright 2014-2023 (C) PG-Strom Developers Team
*
* This program is free software; you can redistribute it and/or modify
* it under the terms of the PostgreSQL License.
*/
#include "cuda_common.h"
/*
* pgstrom_stair_sum_xxxx
*/
static __shared__ union {
uint32_t u32[MAXTHREADS_PER_BLOCK / WARPSIZE];
uint64_t u64[MAXTHREADS_PER_BLOCK / WARPSIZE];
int32_t i32[MAXTHREADS_PER_BLOCK / WARPSIZE];
int64_t i64[MAXTHREADS_PER_BLOCK / WARPSIZE];
float8_t fp64[MAXTHREADS_PER_BLOCK / WARPSIZE];
} __stair_sum_buffer;
template <typename T>
INLINE_FUNCTION(T)
__stair_sum_warp_common(T my_value)
{
T curr = my_value;
T temp;
assert(__activemask() == ~0U);
temp = __shfl_sync(__activemask(), curr, (LaneId() & ~0x01));
if ((LaneId() & 0x01) != 0)
curr += temp;
temp = __shfl_sync(__activemask(), curr, (LaneId() & ~0x03) | 0x01);
if ((LaneId() & 0x02) != 0)
curr += temp;
temp = __shfl_sync(__activemask(), curr, (LaneId() & ~0x07) | 0x03);
if ((LaneId() & 0x04) != 0)
curr += temp;
temp = __shfl_sync(__activemask(), curr, (LaneId() & ~0x0f) | 0x07);
if ((LaneId() & 0x08) != 0)
curr += temp;
temp = __shfl_sync(__activemask(), curr, (LaneId() & ~0x1f) | 0x0f);
if ((LaneId() & 0x10) != 0)
curr += temp;
return curr;
}
PUBLIC_FUNCTION(uint32_t)
pgstrom_stair_sum_binary(bool predicate, uint32_t *p_total_count)
{
uint32_t n_warps = get_local_size() / warpSize;
uint32_t warp_id = get_local_id() / warpSize;
uint32_t mask;
uint32_t sum;
assert(__activemask() == ~0U);
mask = __ballot_sync(__activemask(), predicate);
if (LaneId() == 0)
__stair_sum_buffer.u32[warp_id] = __popc(mask);
__syncthreads();
if (warp_id == 0)
{
uint32_t temp = (LaneId() < n_warps ? __stair_sum_buffer.u32[LaneId()] : 0);
__stair_sum_buffer.u32[LaneId()] = __stair_sum_warp_common(temp);
}
__syncthreads();
if (p_total_count)
*p_total_count = __stair_sum_buffer.u32[warpSize-1];
sum = (warp_id > 0 ? __stair_sum_buffer.u32[warp_id-1] : 0);
__syncthreads();
mask &= ((1U << LaneId()) - 1); /* not include myself */
return sum + __popc(mask);
}
#define PGSTROM_STAIR_SUM_TEMPLATE(SUFFIX, BASETYPE, FIELD) \
PUBLIC_FUNCTION(BASETYPE) \
pgstrom_stair_sum_##SUFFIX(BASETYPE value, BASETYPE *p_total_count) \
{ \
uint32_t n_warps = get_local_size() / warpSize; \
uint32_t warp_id = get_local_id() / warpSize; \
BASETYPE warp_sum; \
BASETYPE sum; \
\
assert(__activemask() == ~0U); \
warp_sum = __stair_sum_warp_common(value); \
if (LaneId() == warpSize - 1) \
__stair_sum_buffer.FIELD[warp_id] = warp_sum; \
__syncthreads(); \
\
if (warp_id == 0) \
{ \
BASETYPE temp = (LaneId() < n_warps \
? __stair_sum_buffer.FIELD[LaneId()] : 0); \
__stair_sum_buffer.FIELD[LaneId()] = __stair_sum_warp_common(temp); \
} \
__syncthreads(); \
\
if (p_total_count) \
*p_total_count = __stair_sum_buffer.FIELD[warpSize-1]; \
sum = (warp_id > 0 ? __stair_sum_buffer.FIELD[warp_id-1] : 0); \
__syncthreads(); \
\
return sum + warp_sum; \
}
PGSTROM_STAIR_SUM_TEMPLATE(uint32, uint32_t, u32)
PGSTROM_STAIR_SUM_TEMPLATE(uint64, uint64_t, u64)
PGSTROM_STAIR_SUM_TEMPLATE(int64, int64_t, i64)
PGSTROM_STAIR_SUM_TEMPLATE(fp64, float8_t, fp64)
#define PGSTROM_LOCAL_MINMAX_TEMPLATE(SUFFIX, BASETYPE, FIELD, OPER, INVAL) \
PUBLIC_FUNCTION(BASETYPE) \
pgstrom_local_##SUFFIX(BASETYPE my_value) \
{ \
int warp_id = get_local_id() / warpSize; \
int n_warps = get_local_size() / warpSize; \
BASETYPE curr = my_value; \
BASETYPE temp; \
\
/* makes warp local min/max */ \
assert(__activemask() == ~0U); \
temp = __shfl_xor_sync(__activemask(), curr, 0x0001); \
curr = OPER(curr, temp); \
temp = __shfl_xor_sync(__activemask(), curr, 0x0002); \
curr = OPER(curr, temp); \
temp = __shfl_xor_sync(__activemask(), curr, 0x0004); \
curr = OPER(curr, temp); \
temp = __shfl_xor_sync(__activemask(), curr, 0x0008); \
curr = OPER(curr, temp); \
temp = __shfl_xor_sync(__activemask(), curr, 0x0010); \
curr = OPER(curr, temp); \
\
if (LaneId() == 0) \
__stair_sum_buffer.FIELD[warp_id] = curr; \
__syncthreads(); \
\
if (warp_id == 0) \
{ \
assert(__activemask() == ~0U); \
curr = (LaneId() < n_warps ? __stair_sum_buffer.FIELD[LaneId()] : INVAL); \
\
temp = __shfl_xor_sync(__activemask(), curr, 0x0001); \
curr = OPER(curr, temp); \
temp = __shfl_xor_sync(__activemask(), curr, 0x0002); \
curr = OPER(curr, temp); \
temp = __shfl_xor_sync(__activemask(), curr, 0x0004); \
curr = OPER(curr, temp); \
temp = __shfl_xor_sync(__activemask(), curr, 0x0008); \
curr = OPER(curr, temp); \
temp = __shfl_xor_sync(__activemask(), curr, 0x0010); \
curr = OPER(curr, temp); \
\
__stair_sum_buffer.FIELD[LaneId()] = curr; \
} \
__syncthreads(); \
curr = __stair_sum_buffer.FIELD[LaneId()]; \
__syncthreads(); \
return curr; \
}
PGSTROM_LOCAL_MINMAX_TEMPLATE(min_int32, int32_t, i32, Min, INT_MAX)
PGSTROM_LOCAL_MINMAX_TEMPLATE(max_int32, int32_t, i32, Max, INT_MIN)
PGSTROM_LOCAL_MINMAX_TEMPLATE(min_int64, int64_t, i64, Min, LONG_MAX)
PGSTROM_LOCAL_MINMAX_TEMPLATE(max_int64, int64_t, i64, Max, LONG_MIN)
PGSTROM_LOCAL_MINMAX_TEMPLATE(min_fp64, float8_t, fp64, Min, DBL_MAX)
PGSTROM_LOCAL_MINMAX_TEMPLATE(max_fp64, float8_t, fp64, Max, -DBL_MAX)
/* ----------------------------------------------------------------
*
* execGpuScanLoadSource and related
*
* ----------------------------------------------------------------
*/
STATIC_FUNCTION(int)
__gpuscan_load_source_row(kern_context *kcxt,
kern_warp_context *wp,
const kern_data_store *kds_src,
const kern_expression *kexp_load_vars,
const kern_expression *kexp_scan_quals,
const kern_expression *kexp_move_vars,
char *dst_kvecs_buffer)
{
uint32_t count;
uint32_t index;
uint32_t wr_pos;
kern_tupitem *tupitem = NULL;
/* compute the next row-index */
count = wp->smx_row_count;
__syncthreads();
if (get_local_id() == 0)
wp->smx_row_count++;
index = get_global_size() * count + get_global_base();
if (index >= kds_src->nitems)
{
if (get_local_id() == 0)
wp->scan_done = 1;
__syncthreads();
return 1;
}
index += get_local_id();
/*
* fetch the outer tuple to scan
*/
if (index < kds_src->nitems)
{
uint32_t offset = KDS_GET_ROWINDEX(kds_src)[index];
assert(offset <= kds_src->usage);
tupitem = (kern_tupitem *)((char *)kds_src +
kds_src->length -
__kds_unpack(offset));
assert((char *)tupitem >= (char *)kds_src &&
(char *)tupitem < (char *)kds_src + kds_src->length);
if (!ExecLoadVarsOuterRow(kcxt,
kexp_load_vars,
kexp_scan_quals,
kds_src,
&tupitem->htup))
tupitem = NULL;
}
/* error checks */
if (__syncthreads_count(kcxt->errcode != ERRCODE_STROM_SUCCESS) > 0)
return -1;
/*
* save the private kvars slot on the combination buffer (depth=0)
*/
wr_pos = WARP_WRITE_POS(wp,0);
wr_pos += pgstrom_stair_sum_binary(tupitem != NULL, &count);
if (get_local_id() == 0)
WARP_WRITE_POS(wp,0) += count;
if (tupitem != NULL)
{
if (!ExecMoveKernelVariables(kcxt,
kexp_move_vars,
dst_kvecs_buffer,
(wr_pos % KVEC_UNITSZ)))
{
assert(kcxt->errcode != ERRCODE_STROM_SUCCESS);
}
}
/* error checks */
if (__syncthreads_count(kcxt->errcode != ERRCODE_STROM_SUCCESS) > 0)
return -1;
/* move to the next depth, if more than blockSize tuples were fetched. */
return (WARP_WRITE_POS(wp,0) >= WARP_READ_POS(wp,0) + get_local_size() ? 1 : 0);
}
/*
* __gpuscan_load_source_block
*/
STATIC_FUNCTION(int)
__gpuscan_load_source_block(kern_context *kcxt,
kern_warp_context *wp,
const kern_data_store *kds_src,
const kern_expression *kexp_load_vars,
const kern_expression *kexp_scan_quals,
const kern_expression *kexp_move_vars,
char *dst_kvecs_buffer)
{
uint32_t wr_pos = wp->lp_wr_pos;
uint32_t rd_pos = wp->lp_rd_pos;
uint32_t block_id;
uint32_t count;
bool has_next_lp_items = false;
HeapTupleHeaderData *htup = NULL;
assert(wr_pos >= rd_pos);
block_id = (get_global_size() / warpSize) * wp->smx_row_count;
if (block_id >= kds_src->nitems || wr_pos >= rd_pos + get_local_size())
{
uint32_t off;
rd_pos += get_local_id();
if (rd_pos < wr_pos)
{
off = wp->lp_items[rd_pos % LP_ITEMS_PER_BLOCK];
htup = (HeapTupleHeaderData *)((char *)kds_src + __kds_unpack(off));
if (!ExecLoadVarsOuterRow(kcxt,
kexp_load_vars,
kexp_scan_quals,
kds_src, htup))
htup = NULL;
}
/* error checks */
if (__syncthreads_count(kcxt->errcode != ERRCODE_STROM_SUCCESS) > 0)
return -1;
if (get_local_id() == 0)
wp->lp_rd_pos = Min(wp->lp_wr_pos,
wp->lp_rd_pos + get_local_size());
/*
* save the private kvars on the warp-buffer
*/
wr_pos = WARP_WRITE_POS(wp,0);
wr_pos += pgstrom_stair_sum_binary(htup != NULL, &count);
if (get_local_id() == 0)
WARP_WRITE_POS(wp,0) += count;
if (htup != NULL)
{
if (!ExecMoveKernelVariables(kcxt,
kexp_move_vars,
dst_kvecs_buffer,
(wr_pos % KVEC_UNITSZ)))
{
assert(kcxt->errcode != ERRCODE_STROM_SUCCESS);
}
}
/* error checks */
if (__syncthreads_count(kcxt->errcode != ERRCODE_STROM_SUCCESS) > 0)
return -1;
/* end-of-scan checks */
if (block_id >= kds_src->nitems && /* no more blocks to fetch */
wp->lp_rd_pos >= wp->lp_wr_pos) /* no more pending tuples */
{
if (get_local_id() == 0)
wp->scan_done = 1;
return 1;
}
/* move to the next depth if more than blockSize tuples were fetched */
return (WARP_WRITE_POS(wp,0) >= WARP_READ_POS(wp,0) + get_local_size() ? 1 : 0);
}
/*
* Here, number of pending tuples (which is saved in the lp_items[]) is
* not enough to run ScanQuals checks. So, we move to the next bunch of
* line-items or next block.
* The pending tuples just passed the MVCC visivility checks, but
* ScanQuals check is not applied yet. We try to run ScanQuals checks
* with maximum number of threads simultaneously, as large as we can.
*/
block_id += (get_global_id() / warpSize);
if (block_id < kds_src->nitems)
{
PageHeaderData *pg_page = KDS_BLOCK_PGPAGE(kds_src, block_id);
BlockNumber block_nr = KDS_BLOCK_BLCKNR(kds_src, block_id);
uint32_t nitems = PageGetMaxOffsetNumber(pg_page);
uint32_t index;
index = wp->lp_count * warpSize + LaneId();
if (index < PageGetMaxOffsetNumber(pg_page))
{
ItemIdData *lpp = &pg_page->pd_linp[index];
assert((char *)lpp < (char *)pg_page + BLCKSZ);
if (ItemIdIsNormal(lpp))
{
htup = (HeapTupleHeaderData *)PageGetItem(pg_page, lpp);
/* for ctid system column reference */
htup->t_ctid.ip_blkid.bi_hi = (uint16_t)(block_nr >> 16);
htup->t_ctid.ip_blkid.bi_lo = (uint16_t)(block_nr & 0xffffU);
htup->t_ctid.ip_posid = index + 1;
}
}
has_next_lp_items = (index + warpSize < nitems);
}
/* put visible tuples on the lp_items[] array */
wr_pos = wp->lp_wr_pos;
wr_pos += pgstrom_stair_sum_binary(htup != NULL, &count);
if (get_local_id() == 0)
wp->lp_wr_pos += count;
if (htup != NULL)
{
wp->lp_items[wr_pos % LP_ITEMS_PER_BLOCK]
= __kds_packed((char *)htup - (char *)kds_src);
}
/* increment the row/line pointer */
if (__syncthreads_count(has_next_lp_items) > 0)
{
if (get_local_id() == 0)
wp->lp_count++;
}
else
{
if (get_local_id() == 0)
{
wp->smx_row_count++;
wp->lp_count = 0;
}
}
return 0; /* stay depth=0 */
}
/*
* __gpuscan_load_source_arrow
*/
STATIC_FUNCTION(int)
__gpuscan_load_source_arrow(kern_context *kcxt,
kern_warp_context *wp,
const kern_data_store *kds_src,
const kern_expression *kexp_load_vars,
const kern_expression *kexp_scan_quals,
const kern_expression *kexp_move_vars,
char *dst_kvecs_buffer)
{
uint32_t count;
uint32_t index;
uint32_t wr_pos;
bool is_valid = false;
/* compute the next row-index */
count = wp->smx_row_count;
__syncthreads();
if (get_local_id() == 0)
wp->smx_row_count++;
index = get_global_size() * count + get_global_base();
if (index >= kds_src->nitems)
{
if (get_local_id() == 0)
wp->scan_done = 1;
return 1;
}
index += get_local_id();
/*
* fetch arrow tuple
*/
if (index < kds_src->nitems)
{
if (ExecLoadVarsOuterArrow(kcxt,
kexp_load_vars,
kexp_scan_quals,
kds_src,
index))
is_valid = true;
}
/* error checks */
if (__syncthreads_count(kcxt->errcode != ERRCODE_STROM_SUCCESS) > 0)
return -1;
/*
* save the private kvars slot on the combination buffer (depth=0)
*/
wr_pos = WARP_WRITE_POS(wp,0);
wr_pos += pgstrom_stair_sum_binary(is_valid, &count);
if (get_local_id() == 0)
WARP_WRITE_POS(wp,0) += count;
if (is_valid)
{
if (!ExecMoveKernelVariables(kcxt,
kexp_move_vars,
dst_kvecs_buffer,
(wr_pos % KVEC_UNITSZ)))
{
assert(kcxt->errcode != ERRCODE_STROM_SUCCESS);
}
}
/* error checks */
if (__syncthreads_count(kcxt->errcode != ERRCODE_STROM_SUCCESS) > 0)
return -1;
/* move to the next depth, if more than blockSize rows were fetched. */
return (WARP_WRITE_POS(wp,0) >= WARP_READ_POS(wp,0) + get_local_size() ? 1 : 0);
}
/*
* __gpuscan_load_source_column (KDS_FORMAT_COLUMN)
*/
INLINE_FUNCTION(GpuCacheSysattr *)
kds_column_get_sysattr(const kern_data_store *kds, uint32_t rowid)
{
const kern_colmeta *cmeta = &kds->colmeta[kds->nr_colmeta - 1];
GpuCacheSysattr *base;
assert(!cmeta->attbyval &&
cmeta->attalign == sizeof(uint32_t) &&
cmeta->attlen == sizeof(GpuCacheSysattr) &&
cmeta->nullmap_offset == 0);
base = (GpuCacheSysattr *)
((char *)kds + __kds_unpack(cmeta->values_offset));
if (rowid < kds->column_nrooms)
return &base[rowid];
return NULL;
}
STATIC_FUNCTION(bool)
kds_column_check_visibility(kern_context *kcxt,
const kern_data_store *kds,
uint32_t rowid)
{
SerializedTransactionState *xstate = SESSION_XACT_STATE(kcxt->session);
GpuCacheSysattr *sysattr = kds_column_get_sysattr(kds, rowid);
assert(xstate != NULL && sysattr != NULL);
if (sysattr->xmin == InvalidTransactionId)
return false;
if (sysattr->xmin != FrozenTransactionId)
{
for (int i=0; i < xstate->nParallelCurrentXids; i++)
{
if (sysattr->xmin == xstate->parallelCurrentXids[i])
goto xmin_is_visible;
}
return false;
}
xmin_is_visible:
if (sysattr->xmax == InvalidTransactionId)
return true;
if (sysattr->xmax == FrozenTransactionId)
return false;
for (int i=0; i < xstate->nParallelCurrentXids; i++)
{
if (sysattr->xmax == xstate->parallelCurrentXids[i])
return false;
}
return true;
}
STATIC_FUNCTION(int)
__gpuscan_load_source_column(kern_context *kcxt,
kern_warp_context *wp,
const kern_data_store *kds_src,
const kern_data_extra *kds_extra,
const kern_expression *kexp_load_vars,
const kern_expression *kexp_scan_quals,
const kern_expression *kexp_move_vars,
char *dst_kvecs_buffer)
{
uint32_t count;
uint32_t index;
uint32_t wr_pos;
bool is_valid = false;
/* fetch next blockSize tuples */
count = wp->smx_row_count;
__syncthreads();
if (get_local_id() == 0)
wp->smx_row_count++;
index = get_global_size() * count + get_global_base();
if (index >= kds_src->nitems)
{
if (get_local_id() == 0)
wp->scan_done = 1;
return 1;
}
index += get_local_id();
/*
* fetch the outer tuple to scan
*/
if (index < kds_src->nitems &&
kds_column_check_visibility(kcxt, kds_src, index))
{
if (ExecLoadVarsOuterColumn(kcxt,
kexp_load_vars,
kexp_scan_quals,
kds_src,
kds_extra,
index))
is_valid = true;
}
/* error checks */
if (__syncthreads_count(kcxt->errcode != ERRCODE_STROM_SUCCESS) > 0)
return -1;
/*
* save the private kvars slot on the combination buffer (depth=0)
*/
wr_pos = WARP_WRITE_POS(wp,0);
wr_pos += pgstrom_stair_sum_binary(is_valid, &count);
if (get_local_id() == 0)
WARP_WRITE_POS(wp,0) += count;
if (is_valid)
{
if (!ExecMoveKernelVariables(kcxt,
kexp_move_vars,
dst_kvecs_buffer,
(wr_pos % KVEC_UNITSZ)))
{
assert(kcxt->errcode != ERRCODE_STROM_SUCCESS);
}
}
/* error checks */
if (__syncthreads_count(kcxt->errcode != ERRCODE_STROM_SUCCESS) > 0)
return -1;
/* move to the next depth if more than 32 htuples were fetched */
return (WARP_WRITE_POS(wp,0) >= WARP_READ_POS(wp,0) + get_local_size() ? 1 : 0);
}
PUBLIC_FUNCTION(int)
execGpuScanLoadSource(kern_context *kcxt,
kern_warp_context *wp,
const kern_data_store *kds_src,
const kern_data_extra *kds_extra,
const kern_expression *kexp_load_vars,
const kern_expression *kexp_scan_quals,
const kern_expression *kexp_move_vars,
char *dst_kvecs_buffer)
{
/*
* Move to the next depth (or projection), if combination buffer (depth=0)
* may overflow on the next action, or we already reached to the KDS tail.
*/
if (wp->scan_done > 0 ||
WARP_WRITE_POS(wp,0) >= WARP_READ_POS(wp,0) + get_local_size())
return 1;
/* no source kernel-vectorized buffer for depth==0 */
kcxt->kvecs_curr_buffer = NULL;
kcxt->kvecs_curr_id = 0;
switch (kds_src->format)
{
case KDS_FORMAT_ROW:
return __gpuscan_load_source_row(kcxt, wp,
kds_src,
kexp_load_vars,
kexp_scan_quals,
kexp_move_vars,
dst_kvecs_buffer);
case KDS_FORMAT_BLOCK:
return __gpuscan_load_source_block(kcxt, wp,
kds_src,
kexp_load_vars,
kexp_scan_quals,
kexp_move_vars,
dst_kvecs_buffer);
case KDS_FORMAT_ARROW:
return __gpuscan_load_source_arrow(kcxt, wp,
kds_src,
kexp_load_vars,
kexp_scan_quals,
kexp_move_vars,
dst_kvecs_buffer);
case KDS_FORMAT_COLUMN:
return __gpuscan_load_source_column(kcxt, wp,
kds_src,
kds_extra,
kexp_load_vars,
kexp_scan_quals,
kexp_move_vars,
dst_kvecs_buffer);
default:
STROM_ELOG(kcxt, "Bug? Unknown KDS format");
break;
}
return -1;
}
/* ------------------------------------------------------------
*
* Routines to manage GpuCache
*
* ------------------------------------------------------------
*/
STATIC_FUNCTION(void)
gpucache_cleanup_row_owner(kern_context *kcxt,
kern_gpucache_redolog *redo,
kern_data_store *kds)
{
uint32_t owner_id;
for (owner_id = get_global_id();
owner_id < redo->nitems;
owner_id += get_global_size())
{
GCacheTxLogCommon *tx_log;
GpuCacheSysattr *sysattr;
uint32_t offset = redo->redo_items[owner_id];
uint32_t rowid;
tx_log = (GCacheTxLogCommon *)
((char *)redo + __kds_unpack(offset));
switch (tx_log->type)
{
case GCACHE_TX_LOG__INSERT:
rowid = ((GCacheTxLogInsert *)tx_log)->rowid;
break;
case GCACHE_TX_LOG__DELETE:
rowid = ((GCacheTxLogDelete *)tx_log)->rowid;
break;
case GCACHE_TX_LOG__COMMIT_INS:
case GCACHE_TX_LOG__COMMIT_DEL:
case GCACHE_TX_LOG__ABORT_INS:
case GCACHE_TX_LOG__ABORT_DEL:
rowid = ((GCacheTxLogXact *)tx_log)->rowid;
break;
default:
STROM_ELOG(kcxt, "unknown GCacheTxLog type");
return;
}
assert(rowid < kds->column_nrooms);
sysattr = kds_column_get_sysattr(kds, rowid);
sysattr->owner = 0;
}
}
STATIC_FUNCTION(void)
gpucache_assign_update_owner(kern_context *kcxt,
kern_gpucache_redolog *redo,
kern_data_store *kds)
{
uint32_t owner_id;
for (owner_id = get_global_id();
owner_id < redo->nitems;
owner_id += get_global_size())
{
GCacheTxLogCommon *tx_log;
GpuCacheSysattr *sysattr;
uint32_t offset = redo->redo_items[owner_id];
uint32_t rowid;
tx_log = (GCacheTxLogCommon *)
((char *)redo + __kds_unpack(offset));
if (tx_log->type == GCACHE_TX_LOG__INSERT)
{
rowid = ((GCacheTxLogInsert *)tx_log)->rowid;
sysattr = kds_column_get_sysattr(kds, rowid);
__atomic_max_uint32(&sysattr->owner, owner_id);
}
else if (tx_log->type == GCACHE_TX_LOG__DELETE)
{
rowid = ((GCacheTxLogDelete *)tx_log)->rowid;
sysattr = kds_column_get_sysattr(kds, rowid);
__atomic_max_uint32(&sysattr->owner, owner_id);
}
}
}
STATIC_FUNCTION(bool)
__gpucache_apply_insert_log(kern_context *kcxt,
kern_data_store *kds,
kern_data_extra *extra,
GpuCacheSysattr *sysattr,
const GCacheTxLogInsert *i_log)
{
const HeapTupleHeaderData *htup = &i_log->htup;
uint32_t rowid = i_log->rowid;
bool heap_hasnull = ((htup->t_infomask & HEAP_HASNULL) != 0);
uint32_t offset = htup->t_hoff;
int j, ncols = Min(kds->ncols, (htup->t_infomask2 & HEAP_NATTS_MASK));
for (j=0; j < ncols; j++)
{
const kern_colmeta *cmeta = &kds->colmeta[j];
char *base;
if (cmeta->nullmap_offset != 0)
{
uint32_t *nullmap = (uint32_t *)
((char *)kds + __kds_unpack(cmeta->nullmap_offset));
if (heap_hasnull && att_isnull(j, htup->t_bits))
{
__atomic_and_uint32(&nullmap[rowid>>5], ~(1U<<(rowid&31)));
continue;
}
else
{
__atomic_or_uint32(&nullmap[rowid>>5], (1U<<(rowid&31)));
}
}
else
{
if (heap_hasnull && att_isnull(j, htup->t_bits))
{
STROM_ELOG(kcxt, "NULL appeared at not-null column");
return false;
}
}
assert(cmeta->values_offset != 0);
base = (char *)kds + __kds_unpack(cmeta->values_offset);
if (cmeta->attlen > 0)
{
offset = TYPEALIGN(cmeta->attalign, offset);
memcpy(base + cmeta->attlen * rowid,
(char *)htup + offset,
cmeta->attlen);
offset += cmeta->attlen;
}
else
{
char *vl_pos;
uint32_t vl_len;
uint32_t vl_off;
assert(cmeta->attlen == -1);
if (!VARATT_NOT_PAD_BYTE((char *)htup + offset))
offset = TYPEALIGN(cmeta->attalign, offset);
vl_pos = (char *)htup + offset;
vl_len = VARSIZE_ANY(vl_pos);
vl_off = __atomic_add_uint64(&extra->usage, MAXALIGN(vl_len));
if (vl_off + vl_len > extra->length)
{
STROM_EREPORT(kcxt, ERRCODE_BUFFER_NO_SPACE,
"gpucache: extra buffer has no space");
return false;
}
memcpy((char *)extra + vl_off,
(char *)htup + offset,
vl_len);
((uint32_t *)base)[rowid] = __kds_packed(vl_off);
offset += vl_len;
}
}
sysattr->xmin = htup->t_choice.t_heap.t_xmin;
sysattr->xmax = htup->t_choice.t_heap.t_xmax;
memcpy(&sysattr->ctid, &htup->t_ctid, sizeof(ItemPointerData));
return true;
}
STATIC_FUNCTION(void)
gpucache_apply_update_logs(kern_context *kcxt,
kern_gpucache_redolog *redo,
kern_data_store *kds,
kern_data_extra *extra)
{
__shared__ uint32_t smx_rowid_max;
uint32_t rowid_max = UINT_MAX;
uint32_t owner_id;
if (get_local_id() == 0)
smx_rowid_max = 0;
__syncthreads();
for (owner_id = get_global_id();
owner_id < redo->nitems;
owner_id += get_global_size())
{
GCacheTxLogCommon *tx_log;
GpuCacheSysattr *sysattr;
uint32_t offset = redo->redo_items[owner_id];
tx_log = (GCacheTxLogCommon *)
((char *)redo + __kds_unpack(offset));
if (tx_log->type == GCACHE_TX_LOG__INSERT)
{
GCacheTxLogInsert *i_log = (GCacheTxLogInsert *)tx_log;
sysattr = kds_column_get_sysattr(kds, i_log->rowid);
if (sysattr->owner == owner_id)
{
__gpucache_apply_insert_log(kcxt, kds, extra, sysattr, i_log);
if (rowid_max == UINT_MAX || rowid_max < i_log->rowid)
rowid_max = i_log->rowid;
}
}
else if (tx_log->type == GCACHE_TX_LOG__DELETE)
{
GCacheTxLogDelete *d_log = (GCacheTxLogDelete *)tx_log;
sysattr = kds_column_get_sysattr(kds, d_log->rowid);
if (sysattr->owner == owner_id)
{
sysattr->xmax = d_log->xid;
if (rowid_max == UINT_MAX || rowid_max < d_log->rowid)
rowid_max = d_log->rowid;
}
}
}
/* update kds->nitems */
if (rowid_max != UINT_MAX)
__atomic_max_uint32(&smx_rowid_max, rowid_max);
if (__syncthreads_count(rowid_max != UINT_MAX) > 0 && get_local_id() == 0)
__atomic_max_uint32(&kds->nitems, smx_rowid_max+1);
}
STATIC_FUNCTION(void)
gpucache_assign_xact_owner(kern_context *kcxt,
kern_gpucache_redolog *redo,
kern_data_store *kds)
{
uint32_t owner_id;
for (owner_id = get_global_id();
owner_id < redo->nitems;
owner_id += get_global_size())
{
GCacheTxLogCommon *tx_log;
GpuCacheSysattr *sysattr;
uint32_t offset = redo->redo_items[owner_id];
uint32_t rowid;
tx_log = (GCacheTxLogCommon *)
((char *)redo + __kds_unpack(offset));
if (tx_log->type == GCACHE_TX_LOG__COMMIT_INS ||
tx_log->type == GCACHE_TX_LOG__COMMIT_DEL ||
tx_log->type == GCACHE_TX_LOG__ABORT_INS ||
tx_log->type == GCACHE_TX_LOG__ABORT_DEL)
{
rowid = ((GCacheTxLogXact *)tx_log)->rowid;
sysattr = kds_column_get_sysattr(kds, rowid);
__atomic_max_uint32(&sysattr->owner, owner_id);
}
}
}
STATIC_FUNCTION(uint64_t)
__gpucache_count_deadspace(kern_data_store *kds,
kern_data_extra *extra,
uint32_t rowid)
{
uint64_t retval = 0;
if (kds->has_varlena)
{
assert(rowid < kds->column_nrooms);
for (int j=0; j < kds->ncols; j++)
{
const kern_colmeta *cmeta = &kds->colmeta[j];
if (cmeta->attlen > 0)
continue;
assert(cmeta->attlen == -1);
if (!KDS_COLUMN_ITEM_ISNULL(kds, cmeta, rowid))
{
uint32_t *base = (uint32_t *)
((char *)kds + __kds_unpack(cmeta->values_offset));
char *vl = (char *)extra + __kds_unpack(base[rowid]);
retval += MAXALIGN(VARSIZE_ANY(vl));
}
}
}
return retval;
}
STATIC_FUNCTION(void)
gpucache_apply_xact_logs(kern_context *kcxt,
kern_gpucache_redolog *redo,
kern_data_store *kds,
kern_data_extra *extra)
{
__shared__ uint32_t smx_rowid_max;
__shared__ uint64_t smx_deadspace;
uint32_t rowid_max = UINT_MAX;
uint32_t owner_id;
uint64_t sz;
if (get_local_id() == 0)
{
smx_rowid_max = 0;
smx_deadspace = 0;
}
__syncthreads();
for (owner_id = get_global_id();
owner_id < redo->nitems;
owner_id += get_global_size())
{
GCacheTxLogXact *tx_log;
GpuCacheSysattr *sysattr;
uint32_t offset = redo->redo_items[owner_id];
tx_log = (GCacheTxLogXact *)
((char *)redo + __kds_unpack(offset));
switch (tx_log->type)
{
case GCACHE_TX_LOG__COMMIT_INS:
sysattr = kds_column_get_sysattr(kds, tx_log->rowid);
if (sysattr->owner == owner_id)
{
sysattr->xmin = FrozenTransactionId;
if (rowid_max == UINT_MAX || rowid_max < tx_log->rowid)
rowid_max = tx_log->rowid;
}
break;
case GCACHE_TX_LOG__COMMIT_DEL:
sysattr = kds_column_get_sysattr(kds, tx_log->rowid);
if (sysattr->owner == owner_id)
{
sysattr->xmax = FrozenTransactionId;
if (rowid_max == UINT_MAX || rowid_max < tx_log->rowid)
rowid_max = tx_log->rowid;
sz = __gpucache_count_deadspace(kds, extra, tx_log->rowid);
if (sz > 0)
__atomic_add_uint64(&smx_deadspace, sz);
}
break;
case GCACHE_TX_LOG__ABORT_INS:
sysattr = kds_column_get_sysattr(kds, tx_log->rowid);
if (sysattr->owner == owner_id)
{
sysattr->xmin = InvalidTransactionId;
if (rowid_max == UINT_MAX || rowid_max < tx_log->rowid)
rowid_max = tx_log->rowid;
sz = __gpucache_count_deadspace(kds, extra, tx_log->rowid);
if (sz > 0)
__atomic_add_uint64(&smx_deadspace, sz);
}
break;
case GCACHE_TX_LOG__ABORT_DEL:
sysattr = kds_column_get_sysattr(kds, tx_log->rowid);
if (sysattr->owner == owner_id)
{