forked from heterodb/pg-strom
-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathxpu_postgis.cu
6313 lines (5834 loc) · 163 KB
/
xpu_postgis.cu
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
/*
* xpu_postgis.cu
*
* Routines of basic PostGIS functions & operators for CUDA GPU devices
* --
* Copyright 2011-2023 (C) KaiGai Kohei <[email protected]>
* Copyright 2014-2023 (C) PG-Strom Developers Team
*
* This program is free software; you can redistribute it and/or modify
* it under the terms of the PostgreSQL License.
*/
#include "xpu_common.h"
#include "xpu_postgis.h"
#include <math.h>
/* ================================================================
*
* Internal Utility Routines
*
* ================================================================ */
/*
* Floating point comparators. (see, liblwgeom_internal.h)
*/
#define FP_TOLERANCE 1e-12
#define FP_IS_ZERO(A) (fabs(A) <= FP_TOLERANCE)
#define FP_MAX(A, B) (((A) > (B)) ? (A) : (B))
#define FP_MIN(A, B) (((A) < (B)) ? (A) : (B))
#define FP_ABS(a) ((a) < (0) ? -(a) : (a))
#define FP_EQUALS(A, B) (fabs((A)-(B)) <= FP_TOLERANCE)
#define FP_NEQUALS(A, B) (fabs((A)-(B)) > FP_TOLERANCE)
#define FP_LT(A, B) (((A) + FP_TOLERANCE) < (B))
#define FP_LTEQ(A, B) (((A) - FP_TOLERANCE) <= (B))
#define FP_GT(A, B) (((A) - FP_TOLERANCE) > (B))
#define FP_GTEQ(A, B) (((A) + FP_TOLERANCE) >= (B))
#define FP_CONTAINS_TOP(A, X, B) (FP_LT(A, X) && FP_LTEQ(X, B))
#define FP_CONTAINS_BOTTOM(A, X, B) (FP_LTEQ(A, X) && FP_LT(X, B))
#define FP_CONTAINS_INCL(A, X, B) (FP_LTEQ(A, X) && FP_LTEQ(X, B))
#define FP_CONTAINS_EXCL(A, X, B) (FP_LT(A, X) && FP_LT(X, B))
#define FP_CONTAINS(A, X, B) FP_CONTAINS_EXCL(A, X, B)
/* swap values */
template <typename T>
INLINE_FUNCTION(void)
__swap(T &value_x, T &value_y)
{
T temp;
temp = value_x;
value_x = value_y;
value_y = temp;
}
INLINE_FUNCTION(bool)
geometry_is_collection(const xpu_geometry_t *geom)
{
/* see lw_dist2d_is_collection */
if (geom->type == GEOM_TINTYPE ||
geom->type == GEOM_MULTIPOINTTYPE ||
geom->type == GEOM_MULTILINETYPE ||
geom->type == GEOM_MULTIPOLYGONTYPE ||
geom->type == GEOM_COLLECTIONTYPE ||
geom->type == GEOM_MULTICURVETYPE ||
geom->type == GEOM_MULTISURFACETYPE ||
geom->type == GEOM_COMPOUNDTYPE ||
geom->type == GEOM_POLYHEDRALSURFACETYPE)
return true;
return false;
}
STATIC_FUNCTION(bool)
setup_geometry_rawsize(xpu_geometry_t *geom)
{
switch (geom->type)
{
case GEOM_POINTTYPE:
case GEOM_LINETYPE:
case GEOM_TRIANGLETYPE:
case GEOM_CIRCSTRINGTYPE:
geom->rawsize = (sizeof(double) *
GEOM_FLAGS_NDIMS(geom->flags) * geom->nitems);
return true;
case GEOM_POLYGONTYPE:
{
size_t rawsize = LONGALIGN(sizeof(uint32_t) * geom->nitems);
const char *rawdata = geom->rawdata;
uint32_t __nitems;
for (int i=0; i < geom->nitems; i++)
{
memcpy(&__nitems, rawdata, sizeof(uint32_t));
rawdata += sizeof(uint32_t);
rawsize += (sizeof(double) *
GEOM_FLAGS_NDIMS(geom->flags) * __nitems);
}
geom->rawsize = rawsize;
}
return true;
case GEOM_MULTIPOINTTYPE:
case GEOM_MULTILINETYPE:
case GEOM_MULTIPOLYGONTYPE:
case GEOM_COLLECTIONTYPE:
case GEOM_COMPOUNDTYPE:
case GEOM_CURVEPOLYTYPE:
case GEOM_MULTICURVETYPE:
case GEOM_MULTISURFACETYPE:
case GEOM_POLYHEDRALSURFACETYPE:
case GEOM_TINTYPE:
{
const char *pos = geom->rawdata;
for (int i=0; i < geom->nitems; i++)
{
xpu_geometry_t __geom;
__geom.expr_ops = &xpu_geometry_ops;
__geom.type = __Fetch((int32_t *)pos);
pos += sizeof(int32_t);
__geom.flags = geom->flags;
__geom.nitems = __Fetch((uint32_t *)pos);
pos += sizeof(uint32_t);
__geom.rawdata = pos;
if (!setup_geometry_rawsize(&__geom))
return false;
pos += __geom.rawsize;
}
geom->rawsize = (pos - geom->rawdata);
}
return true;
default:
/* unknown geometry type */
break;
}
return false;
}
STATIC_FUNCTION(const char *)
geometry_load_subitem(xpu_geometry_t *gsub,
const xpu_geometry_t *geom,
const char *pos, int index,
kern_context *kcxt = NULL)
{
switch (geom->type)
{
case GEOM_POINTTYPE:
case GEOM_LINETYPE:
case GEOM_TRIANGLETYPE:
case GEOM_CIRCSTRINGTYPE:
/* no sub-geometry */
if (kcxt)
STROM_ELOG(kcxt, "geometry data curruption (no sub-items)");
break;
case GEOM_POLYGONTYPE:
if (index == 0)
pos = geom->rawdata + LONGALIGN(sizeof(int32_t) * geom->nitems);
else if (index >= geom->nitems)
break;
gsub->expr_ops = &xpu_geometry_ops;
gsub->type = GEOM_LINETYPE;
gsub->flags = geom->flags;
gsub->srid = geom->srid;
gsub->nitems = __Fetch(((uint32_t *)geom->rawdata) + index);
gsub->rawdata = pos;
gsub->bbox = geom->bbox;
setup_geometry_rawsize(gsub);
pos += gsub->rawsize;
if (pos > geom->rawdata + geom->rawsize)
{
if (kcxt)
STROM_ELOG(kcxt,"geometry data curruption (polygon)");
break;
}
return pos;
case GEOM_MULTIPOINTTYPE:
case GEOM_MULTILINETYPE:
case GEOM_MULTIPOLYGONTYPE:
case GEOM_COLLECTIONTYPE:
case GEOM_COMPOUNDTYPE:
case GEOM_CURVEPOLYTYPE:
case GEOM_MULTICURVETYPE:
case GEOM_MULTISURFACETYPE:
case GEOM_POLYHEDRALSURFACETYPE:
case GEOM_TINTYPE:
if (index == 0)
pos = geom->rawdata;
else if (index >= geom->nitems)
break;
gsub->expr_ops = &xpu_geometry_ops;
gsub->type = __Fetch((int32_t *)pos);
pos += sizeof(int32_t);
gsub->flags = geom->flags;
gsub->srid = geom->srid;
gsub->nitems = __Fetch((uint32_t *)pos);
pos += sizeof(uint32_t);
gsub->rawdata = pos;
gsub->bbox = geom->bbox;
setup_geometry_rawsize(gsub);
pos += gsub->rawsize;
if (pos > geom->rawdata + geom->rawsize)
{
if (kcxt)
STROM_ELOG(kcxt, "geometry data curruption (collection)");
break;
}
return pos;
default:
/* unknown geometry type */
break;
}
memset(gsub, 0, sizeof(xpu_geometry_t));
return NULL;
}
STATIC_FUNCTION(bool)
geometry_is_empty(const xpu_geometry_t *geom)
{
if (geometry_is_collection(geom))
{
xpu_geometry_t __geom;
const char *pos = NULL;
for (int i=0; i < geom->nitems; i++)
{
pos = geometry_load_subitem(&__geom, geom, pos, i);
if (!geometry_is_empty(&__geom))
return false;
}
return true; /* empty */
}
return (geom->nitems == 0 ? true : false);
}
/* ================================================================
*
* GSERIALIZED v1/v2 (see, gserialized1.h and gserialized2.h)
*
* ================================================================
*/
INLINE_FUNCTION(int32_t)
__gserialized_get_srid(const __GSERIALIZED *gs)
{
int32_t srid;
/* Only the first 21 bits are set. */
srid = (((uint32_t)gs->srid[0] << 16) |
((uint32_t)gs->srid[1] << 8) |
((uint32_t)gs->srid[2])) & 0x001fffffU;
/* 0 is our internal unknown value */
return (srid == 0 ? SRID_UNKNOWN : srid);
}
STATIC_FUNCTION(bool)
__geometry_datum_ref_v1(kern_context *kcxt,
xpu_geometry_t *geom,
__GSERIALIZED *gs, int32_t sz)
{
/* see lwgeom_from_gserialized1() */
uint32_t gs_type;
uint16_t geom_flags = 0;
char *rawdata = gs->data;
if ((gs->gflags & G1FLAG_Z) != 0)
geom_flags |= GEOM_FLAG__Z;
if ((gs->gflags & G1FLAG_M) != 0)
geom_flags |= GEOM_FLAG__M;
if ((gs->gflags & G1FLAG_BBOX) != 0)
geom_flags |= GEOM_FLAG__BBOX;
if ((gs->gflags & G1FLAG_GEODETIC) != 0)
geom_flags |= GEOM_FLAG__GEODETIC;
if ((gs->gflags & G1FLAG_SOLID) != 0)
geom_flags |= GEOM_FLAG__SOLID;
memset(geom, 0, sizeof(xpu_geometry_t));
geom->expr_ops = &xpu_geometry_ops;
geom->flags = geom_flags;
geom->srid = __gserialized_get_srid(gs);
if ((geom->flags & GEOM_FLAG__BBOX) != 0)
{
geom->bbox = (geom_bbox *)rawdata;
rawdata += geometry_bbox_size(geom_flags);
}
memcpy(&gs_type, rawdata, sizeof(uint32_t));
rawdata += sizeof(uint32_t);
if (GEOM_TYPE_IS_VALID(gs_type))
geom->type = gs_type;
else
{
STROM_ELOG(kcxt, "geometry data v1 has unsupported type");
return false;
}
memcpy(&geom->nitems, rawdata, sizeof(uint32_t));
rawdata += sizeof(uint32_t);
geom->rawdata = rawdata;
if (!setup_geometry_rawsize(geom) ||
geom->rawdata + geom->rawsize > gs->data + sz)
{
STROM_ELOG(kcxt, "geometry data v1 corrupted");
return false;
}
/*
* NOTE: Unlike CPU version of lwgeom_from_gserialized1(),
* we don't generate boundary box here, even if raw geometry
* datum has no boundary box unexpectedly. It is mandatorily
* generated by PostGIS, thus the code to construct bounday
* box just consumes device memory footpoint, and we have no
* proper way for code debugging.
*/
return true;
}
/* flags of GSERIALIZED v2 */
STATIC_FUNCTION(bool)
__geometry_datum_ref_v2(kern_context *kcxt,
xpu_geometry_t *geom,
__GSERIALIZED *gs, int32_t sz)
{
/* see lwgeom_from_gserialized2() */
uint32_t gs_type;
uint16_t geom_flags = 0;
char *rawdata = gs->data;
/* parse version.2 flags */
if ((gs->gflags & G2FLAG_Z) != 0)
geom_flags |= GEOM_FLAG__Z;
if ((gs->gflags & G2FLAG_M) != 0)
geom_flags |= GEOM_FLAG__M;
if ((gs->gflags & G2FLAG_BBOX) != 0)
geom_flags |= GEOM_FLAG__BBOX;
if ((gs->gflags & G2FLAG_GEODETIC) != 0)
geom_flags |= GEOM_FLAG__GEODETIC;
if ((gs->gflags & G2FLAG_EXTENDED) != 0)
{
uint64_t ex_flags;
memcpy(&ex_flags, rawdata, sizeof(uint64_t));
if ((ex_flags & G2FLAG_X_SOLID) != 0)
geom_flags |= GEOM_FLAG__SOLID;
rawdata += sizeof(uint64_t);
}
memset(geom, 0, sizeof(xpu_geometry_t));
geom->expr_ops = &xpu_geometry_ops;
geom->flags = geom_flags;
geom->srid = __gserialized_get_srid(gs);
if ((geom->flags & GEOM_FLAG__BBOX) != 0)
{
geom->bbox = (geom_bbox *)rawdata;
rawdata += geometry_bbox_size(geom_flags);
}
memcpy(&gs_type, rawdata, sizeof(uint32_t));
rawdata += sizeof(uint32_t);
if (GEOM_TYPE_IS_VALID(gs_type))
geom->type = gs_type;
else
{
STROM_ELOG(kcxt, "geometry data v2 has unsupported type");
return false;
}
memcpy(&geom->nitems, rawdata, sizeof(uint32_t));
rawdata += sizeof(uint32_t);
geom->rawdata = rawdata;
if (!setup_geometry_rawsize(geom) ||
geom->rawdata + geom->rawsize > gs->data + sz)
{
STROM_ELOG(kcxt, "geometry data v2 corrupted");
return false;
}
/*
* NOTE: Unlike CPU version of lwgeom_from_gserialized1(),
* we don't generate boundary box here, even if raw geometry
* datum has no boundary box unexpectedly. It is mandatorily
* generated by PostGIS, thus the code to construct bounday
* box just consumes device memory footpoint, and we have no
* proper way for code debugging.
*/
return true;
}
INLINE_FUNCTION(bool)
xpu_geometry_is_valid(kern_context *kcxt, xpu_geometry_t *geom)
{
if (GEOM_TYPE_IS_VALID(geom->type))
return true;
if (geom->type != GEOM_INVALID_VARLENA)
{
STROM_CPU_FALLBACK(kcxt, "unknown geometry type");
}
else if (VARATT_IS_EXTERNAL(geom->rawdata) ||
VARATT_IS_COMPRESSED(geom->rawdata))
{
STROM_CPU_FALLBACK(kcxt, "geometry datum is compressed or external");
}
else
{
__GSERIALIZED *g = (__GSERIALIZED *)VARDATA_ANY(geom->rawdata);
int32_t sz = VARSIZE_ANY_EXHDR(geom->rawdata);
if ((g->gflags & G2FLAG_VER_0) != 0)
return __geometry_datum_ref_v2(kcxt, geom, g, sz);
else
return __geometry_datum_ref_v1(kcxt, geom, g, sz);
}
return false;
}
STATIC_FUNCTION(bool)
xpu_geometry_datum_heap_read(kern_context *kcxt,
const void *addr,
xpu_datum_t *__result)
{
xpu_geometry_t *geom = (xpu_geometry_t *)__result;
memset(geom, 0, sizeof(xpu_geometry_t));
geom->expr_ops = &xpu_geometry_ops;
geom->type = GEOM_INVALID_VARLENA;
geom->rawdata = (const char *)addr;
return true;
}
STATIC_FUNCTION(bool)
xpu_geometry_datum_arrow_read(kern_context *kcxt,
const kern_data_store *kds,
const kern_colmeta *cmeta,
uint32_t kds_index,
xpu_datum_t *__result)
{
STROM_ELOG(kcxt, "xpu_geometry_t does not support Arrow type mapping");
return false;
}
STATIC_FUNCTION(bool)
xpu_geometry_datum_kvec_load(kern_context *kcxt,
const kvec_datum_t *__kvecs,
uint32_t kvecs_id,
xpu_datum_t *__result)
{
const kvec_geometry_t *kvecs = (const kvec_geometry_t *)__kvecs;
xpu_geometry_t *result = (xpu_geometry_t *)__result;
result->expr_ops = &xpu_geometry_ops;
result->type = kvecs->type[kvecs_id];
result->flags = kvecs->flags[kvecs_id];
result->srid = kvecs->srid[kvecs_id];
result->nitems = kvecs->nitems[kvecs_id];
result->rawsize = kvecs->rawsize[kvecs_id];
result->rawdata = kvecs->rawdata[kvecs_id];
result->bbox = kvecs->bbox[kvecs_id];
return true;
}
STATIC_FUNCTION(bool)
xpu_geometry_datum_kvec_save(kern_context *kcxt,
const xpu_datum_t *__xdatum,
kvec_datum_t *__kvecs,
uint32_t kvecs_id)
{
const xpu_geometry_t *xdatum = (const xpu_geometry_t *)__xdatum;
kvec_geometry_t *kvecs = (kvec_geometry_t *)__kvecs;
kvecs->type[kvecs_id] = xdatum->type;
kvecs->flags[kvecs_id] = xdatum->flags;
kvecs->srid[kvecs_id] = xdatum->srid;
kvecs->nitems[kvecs_id] = xdatum->nitems;
kvecs->rawsize[kvecs_id] = xdatum->rawsize;
kvecs->rawdata[kvecs_id] = xdatum->rawdata;
kvecs->bbox[kvecs_id] = xdatum->bbox;
return true;
}
STATIC_FUNCTION(bool)
xpu_geometry_datum_kvec_copy(kern_context *kcxt,
const kvec_datum_t *__kvecs_src,
uint32_t kvecs_src_id,
kvec_datum_t *__kvecs_dst,
uint32_t kvecs_dst_id)
{
const kvec_geometry_t *kvecs_src = (const kvec_geometry_t *)__kvecs_src;
kvec_geometry_t *kvecs_dst = (kvec_geometry_t *)__kvecs_dst;
kvecs_dst->type[kvecs_dst_id] = kvecs_src->type[kvecs_src_id];
kvecs_dst->flags[kvecs_dst_id] = kvecs_src->flags[kvecs_src_id];
kvecs_dst->srid[kvecs_dst_id] = kvecs_src->srid[kvecs_src_id];
kvecs_dst->nitems[kvecs_dst_id] = kvecs_src->nitems[kvecs_src_id];
kvecs_dst->rawsize[kvecs_dst_id] = kvecs_src->rawsize[kvecs_src_id];
kvecs_dst->rawdata[kvecs_dst_id] = kvecs_src->rawdata[kvecs_src_id];
kvecs_dst->bbox[kvecs_dst_id] = kvecs_src->bbox[kvecs_src_id];
return true;
}
STATIC_FUNCTION(int)
xpu_geometry_datum_write(kern_context *kcxt,
char *buffer,
const kern_colmeta *cmeta,
const xpu_datum_t *xdatum)
{
const xpu_geometry_t *geom = (const xpu_geometry_t *)xdatum;
uint8_t gflags = G2FLAG_VER_0;
uint64_t ex_flags = 0;
uint32_t gs_type = geom->type;
int len;
if (XPU_DATUM_ISNULL(geom))
return 0;
/* special case if geometry type is not touched */
if (geom->type == GEOM_INVALID_VARLENA)
{
len = VARSIZE_ANY(geom->rawdata);
if (buffer)
memcpy(buffer, geom->rawdata, len);
return len;
}
/* setup flag bits */
if ((geom->flags & GEOM_FLAG__Z) != 0)
gflags |= G2FLAG_Z;
if ((geom->flags & GEOM_FLAG__M) != 0)
gflags |= G2FLAG_M;
if (geom->bbox)
gflags |= G2FLAG_BBOX;
if ((geom->flags & GEOM_FLAG__GEODETIC) != 0)
gflags |= G2FLAG_GEODETIC;
if ((geom->flags & GEOM_FLAG__SOLID) != 0)
{
gflags |= G2FLAG_EXTENDED;
ex_flags |= G2FLAG_X_SOLID;
}
/* write out header portion */
len = VARHDRSZ + offsetof(__GSERIALIZED, data);
if (buffer)
{
__GSERIALIZED gs;
gs.srid[0] = (geom->srid >> 16) & 0xff;
gs.srid[1] = (geom->srid >> 8) & 0xff;
gs.srid[2] = (geom->srid & 0xff);
gs.gflags = gflags;
memcpy(buffer + VARHDRSZ, &gs, offsetof(__GSERIALIZED, data));
}
if ((gflags & G2FLAG_EXTENDED) != 0)
{
if (buffer)
memcpy(buffer + len, &ex_flags, sizeof(uint64_t));
len += sizeof(uint64_t);
}
/* boundary box */
if ((gflags & G2FLAG_BBOX) != 0)
{
size_t sz = geometry_bbox_size(geom->flags);
if (buffer)
memcpy(buffer + len, geom->bbox, sz);
len += sz;
}
/* geometry type */
if (buffer)
memcpy(buffer + len, &gs_type, sizeof(uint32_t));
len += sizeof(uint32_t);
/* number of items */
if (buffer)
memcpy(buffer + len, &geom->nitems, sizeof(uint32_t));
len += sizeof(uint32_t);
/* rawdata */
if (buffer)
memcpy(buffer + len, geom->rawdata, geom->rawsize);
len += geom->rawsize;
/* set size */
if (buffer)
SET_VARSIZE(buffer, len);
return len;
}
STATIC_FUNCTION(bool)
xpu_geometry_datum_hash(kern_context *kcxt,
uint32_t *p_hash,
xpu_datum_t *arg)
{
STROM_ELOG(kcxt, "geometry type has no hash function");
return false;
}
STATIC_FUNCTION(bool)
xpu_geometry_datum_comp(kern_context *kcxt,
int *p_comp,
xpu_datum_t *__a,
xpu_datum_t *__b)
{
STROM_ELOG(kcxt, "geometry type has no compare function");
return false;
}
PGSTROM_SQLTYPE_OPERATORS(geometry,false,4,-1);
/* ================================================================
*
* box2df (bounding-box) input/output functions
*
* ================================================================
*/
STATIC_FUNCTION(bool)
xpu_box2df_datum_heap_read(kern_context *kcxt,
const void *addr,
xpu_datum_t *__result)
{
xpu_box2df_t *result = (xpu_box2df_t *)__result;
result->expr_ops = &xpu_box2df_ops;
memcpy(&result->value, addr, sizeof(geom_bbox_2d));
return true;
}
STATIC_FUNCTION(bool)
xpu_box2df_datum_arrow_read(kern_context *kcxt,
const kern_data_store *kds,
const kern_colmeta *cmeta,
uint32_t kds_index,
xpu_datum_t *__result)
{
STROM_ELOG(kcxt, "xpu_box2df_t does not support Arrow type mapping");
return false;
}
STATIC_FUNCTION(bool)
xpu_box2df_datum_kvec_load(kern_context *kcxt,
const kvec_datum_t *__kvecs,
uint32_t kvecs_id,
xpu_datum_t *__result)
{
const kvec_box2df_t *kvecs = (const kvec_box2df_t *)__kvecs;
xpu_box2df_t *result = (xpu_box2df_t *)__result;
result->expr_ops = &xpu_box2df_ops;
result->value.xmin = kvecs->xmin[kvecs_id];
result->value.xmax = kvecs->xmax[kvecs_id];
result->value.ymin = kvecs->ymin[kvecs_id];
result->value.ymax = kvecs->ymax[kvecs_id];
return true;
}
STATIC_FUNCTION(bool)
xpu_box2df_datum_kvec_save(kern_context *kcxt,
const xpu_datum_t *__xdatum,
kvec_datum_t *__kvecs,
uint32_t kvecs_id)
{
const xpu_box2df_t *xdatum = (const xpu_box2df_t *)__xdatum;
kvec_box2df_t *kvecs = (kvec_box2df_t *)__kvecs;
kvecs->xmin[kvecs_id] = xdatum->value.xmin;
kvecs->xmax[kvecs_id] = xdatum->value.xmax;
kvecs->ymin[kvecs_id] = xdatum->value.ymin;
kvecs->ymax[kvecs_id] = xdatum->value.ymax;
return true;
}
STATIC_FUNCTION(bool)
xpu_box2df_datum_kvec_copy(kern_context *kcxt,
const kvec_datum_t *__kvecs_src,
uint32_t kvecs_src_id,
kvec_datum_t *__kvecs_dst,
uint32_t kvecs_dst_id)
{
const kvec_box2df_t *kvecs_src = (const kvec_box2df_t *)__kvecs_src;
kvec_box2df_t *kvecs_dst = (kvec_box2df_t *)__kvecs_dst;
kvecs_dst->xmin[kvecs_dst_id] = kvecs_src->xmin[kvecs_src_id];
kvecs_dst->xmax[kvecs_dst_id] = kvecs_src->xmax[kvecs_src_id];
kvecs_dst->ymin[kvecs_dst_id] = kvecs_src->ymin[kvecs_src_id];
kvecs_dst->ymax[kvecs_dst_id] = kvecs_src->ymax[kvecs_src_id];
return true;
}
STATIC_FUNCTION(int)
xpu_box2df_datum_write(kern_context *kcxt,
char *buffer,
const kern_colmeta *cmeta,
const xpu_datum_t *xdatum)
{
xpu_box2df_t *bbox = (xpu_box2df_t *)xdatum;
if (buffer)
memcpy(buffer, &bbox->value, sizeof(geom_bbox_2d));
return sizeof(geom_bbox_2d);
}
STATIC_FUNCTION(bool)
xpu_box2df_datum_hash(kern_context *kcxt,
uint32_t *p_hash,
xpu_datum_t *xdatum)
{
STROM_ELOG(kcxt, "box2df supports no hash function");
return false;
}
STATIC_FUNCTION(bool)
xpu_box2df_datum_comp(kern_context *kcxt,
int *p_comp,
xpu_datum_t *__a,
xpu_datum_t *__b)
{
STROM_ELOG(kcxt, "box2df type has no compare function");
return false;
}
PGSTROM_SQLTYPE_OPERATORS(box2df,false,1,sizeof(geom_bbox_2d));
/* ================================================================
*
* Basic geometry constructor and related
*
* ================================================================
*/
PUBLIC_FUNCTION(bool)
pgfn_st_setsrid(XPU_PGFUNCTION_ARGS)
{
xpu_geometry_t *geom = (xpu_geometry_t *)__result;
xpu_int4_t srid;
const kern_expression *karg = KEXP_FIRST_ARG(kexp);
assert(KEXP_IS_VALID(karg,geometry));
if (!EXEC_KERN_EXPRESSION(kcxt, karg, (xpu_datum_t *)geom))
return false;
karg = KEXP_NEXT_ARG(karg);
assert(KEXP_IS_VALID(karg,int4));
if (!EXEC_KERN_EXPRESSION(kcxt, karg, &srid))
return false;
if (XPU_DATUM_ISNULL(geom) || XPU_DATUM_ISNULL(&srid))
geom->expr_ops = NULL;
else if (!xpu_geometry_is_valid(kcxt, geom))
return false;
else
{
assert(geom->expr_ops == &xpu_geometry_ops);
if (srid.value <= 0)
geom->srid = SRID_UNKNOWN;
else if (srid.value > SRID_MAXIMUM)
geom->srid = SRID_USER_MAXIMUM + 1 +
(srid.value % (SRID_MAXIMUM - SRID_USER_MAXIMUM - 1));
else
geom->srid = srid.value;
}
return true;
}
PUBLIC_FUNCTION(bool)
pgfn_st_point(XPU_PGFUNCTION_ARGS)
{
return pgfn_st_makepoint2(kcxt, kexp, __result);
}
PUBLIC_FUNCTION(bool)
pgfn_st_makepoint2(XPU_PGFUNCTION_ARGS)
{
KEXP_PROCESS_ARGS2(geometry, float8, x, float8, y);
if (XPU_DATUM_ISNULL(&x) || XPU_DATUM_ISNULL(&y))
result->expr_ops = NULL;
else
{
double *rawdata = (double *)kcxt_alloc(kcxt, 2 * sizeof(double));
if (!rawdata)
{
STROM_ELOG(kcxt, "out of memory");
return false;
}
rawdata[0] = x.value;
rawdata[1] = y.value;
result->expr_ops = &xpu_geometry_ops;
result->type = GEOM_POINTTYPE;
result->flags = 0;
result->srid = SRID_UNKNOWN;
result->nitems = 1;
result->rawsize = 2 * sizeof(double);
result->rawdata = (char *)rawdata;
result->bbox = NULL;
}
return true;
}
PUBLIC_FUNCTION(bool)
pgfn_st_makepoint3(XPU_PGFUNCTION_ARGS)
{
KEXP_PROCESS_ARGS3(geometry, float8, x, float8, y, float8, z);
if (XPU_DATUM_ISNULL(&x) || XPU_DATUM_ISNULL(&y) || XPU_DATUM_ISNULL(&z))
result->expr_ops = NULL;
else
{
double *rawdata = (double *)kcxt_alloc(kcxt, 3 * sizeof(double));
if (!rawdata)
{
STROM_ELOG(kcxt, "out of memory");
return false;
}
rawdata[0] = x.value;
rawdata[1] = y.value;
rawdata[2] = z.value;
result->expr_ops = &xpu_geometry_ops;
result->type = GEOM_POINTTYPE;
result->flags = GEOM_FLAG__Z;
result->srid = SRID_UNKNOWN;
result->nitems = 1;
result->rawsize = 3 * sizeof(double);
result->rawdata = (char *)rawdata;
result->bbox = NULL;
}
return true;
}
PUBLIC_FUNCTION(bool)
pgfn_st_makepoint4(XPU_PGFUNCTION_ARGS)
{
KEXP_PROCESS_ARGS4(geometry,
float8, x, float8, y,
float8, z, float8, m);
if (XPU_DATUM_ISNULL(&x) || XPU_DATUM_ISNULL(&y) ||
XPU_DATUM_ISNULL(&z) || XPU_DATUM_ISNULL(&m))
result->expr_ops = NULL;
else
{
double *rawdata = (double *)kcxt_alloc(kcxt, 4 * sizeof(double));
if (!rawdata)
{
STROM_ELOG(kcxt, "out of memory");
return false;
}
rawdata[0] = x.value;
rawdata[1] = y.value;
rawdata[2] = z.value;
rawdata[3] = m.value;
result->expr_ops = &xpu_geometry_ops;
result->type = GEOM_POINTTYPE;
result->flags = GEOM_FLAG__Z | GEOM_FLAG__M;
result->srid = SRID_UNKNOWN;
result->nitems = 1;
result->rawsize = 4 * sizeof(double);
result->rawdata = (char *)rawdata;
result->bbox = NULL;
}
return true;
}
/* ================================================================
*
* Internal utility functions
*
* ================================================================
*/
#define PT_INSIDE 1
#define PT_BOUNDARY 0
#define PT_OUTSIDE (-1)
#define PT_ERROR 9999
INLINE_FUNCTION(const char *)
__loadPoint2d(POINT2D *pt, const char *rawdata, uint32_t unitsz)
{
memcpy(pt, rawdata, sizeof(POINT2D));
return rawdata + unitsz;
}
INLINE_FUNCTION(const char *)
__loadPoint2dIndex(POINT2D *pt,
const char *rawdata, uint32_t unitsz, uint32_t index)
{
rawdata += unitsz * index;
memcpy(pt, rawdata, sizeof(POINT2D));
return rawdata + unitsz;
}
INLINE_FUNCTION(int)
__geom_segment_side(const POINT2D *p1, const POINT2D *p2, const POINT2D *q)
{
double side = ((q->x - p1->x) * (p2->y - p1->y) -
(p2->x - p1->x) * (q->y - p1->y));
return (side < 0.0 ? -1 : (side > 0.0 ? 1 : 0));
}
INLINE_FUNCTION(bool)
__geom_pt_in_arc(const POINT2D *P,
const POINT2D *A1,
const POINT2D *A2,
const POINT2D *A3)
{
return __geom_segment_side(A1, A3, A2) == __geom_segment_side(A1, A3, P);
}
INLINE_FUNCTION(bool)
__geom_pt_in_seg(const POINT2D *P,
const POINT2D *A1,
const POINT2D *A2)
{
return ((A1->x <= P->x && P->x < A2->x) ||
(A1->x >= P->x && P->x > A2->x) ||
(A1->y <= P->y && P->y < A2->y) ||
(A1->y >= P->y && P->y > A2->y));
}
INLINE_FUNCTION(int32_t)
__geom_pt_within_seg(const POINT2D *P,
const POINT2D *A1,
const POINT2D *A2)
{
if (((A1->x <= P->x && P->x <= A2->x) ||
(A2->x <= P->x && P->x <= A1->x)) &&
((A1->y <= P->y && P->y <= A2->y) ||
(A2->y <= P->y && P->y <= A1->y)))
{
if ((A1->x == P->x && A1->y == P->y) ||
(A2->x == P->x && A2->y == P->y))
return PT_BOUNDARY;
return PT_INSIDE;
}
return PT_OUTSIDE;
}
/* ================================================================
*
* Basic Operators related to boundary-box
*
* ================================================================
*/
INLINE_FUNCTION(bool)
__geom_bbox_2d_is_empty(const geom_bbox_2d *bbox)
{
return isnan(bbox->xmin);
}
#ifndef __CUDACC__
/* double to float with round-down */
INLINE_FUNCTION(float)
__double2float_rd(double dval)
{
float fval;
if (isnan(dval) || isinf(dval))
fval = dval;
else if (dval > (double)FLT_MAX)
fval = FLT_MAX;
else if (dval <= (double)-FLT_MAX)
fval = -FLT_MAX;
else
{
fval = dval;
if (fval > dval)
fval = nextafterf(fval, -FLT_MAX);
}
return fval;
}
/* double to float with round-up */
INLINE_FUNCTION(float)
__double2float_ru(double dval)
{
float fval;
if (isnan(dval) || isinf(dval))
fval = dval;
else if (dval >= (double)FLT_MAX)
fval = FLT_MAX;
else if (dval < (double)-FLT_MAX)
fval = -FLT_MAX;
else
{
fval = dval;
if (fval < dval)
fval = nextafterf(fval, FLT_MAX);
}
return fval;
}
#endif /* __CUDACC__ */
/* see, gserialized_datum_get_box2df_p() */
STATIC_FUNCTION(bool)
__geometry_get_bbox2d(kern_context *kcxt,
const xpu_geometry_t *geom, geom_bbox_2d *bbox)
{
POINT2D pt;
uint32_t unitsz;
const char *rawdata;
double xmin, xmax;
double ymin, ymax;
xpu_geometry_t temp;
const char *pos;
/* geometry already has bounding-box? */
if (geom->bbox)
{
memcpy(bbox, &geom->bbox->d2, sizeof(geom_bbox_2d));
return true;
}