build.gradle

buildscript {
    ext {
        corda_release_group = 'net.corda'
        corda_release_version = '4.8.11'
        tokens_release_group = 'com.r3.corda.lib.tokens'
        tokens_release_version = '1.1'
        accounts_release_group = 'com.r3.corda.lib.accounts'
        accounts_release_version = '1.1-SNAPSHOT'
        corda_gradle_plugins_version = '5.0.12'
        mavenVersion = '3.1.0'
        maven_resolver_version = "1.1.1"
        kotlin_version = '1.2.71'
        junit_version = '4.12'
        quasar_version = '0.7.10'
        log4j_version = '2.9.1'
        confidential_id_release_group = "com.r3.corda.lib.ci"
        confidential_id_release_version = "1.0"
        spring_boot_version = '2.0.2.RELEASE'
        spring_boot_gradle_plugin_version = '2.0.2.RELEASE'
        publicArtifactURL='https://download.corda.net/maven'
    }

    repositories {
        mavenCentral()
        maven { url "${publicArtifactURL}/corda-releases" }
        // as last resort, check our backup of now defunc JCenter repo
        maven { url "${publicArtifactURL}/jcenter-backup" }
    }

    dependencies {
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlin_version"
        classpath "net.corda.plugins:cordformation:$corda_gradle_plugins_version"
        classpath "net.corda.plugins:quasar-utils:$corda_gradle_plugins_version"
        classpath "net.corda.plugins:cordapp:$corda_gradle_plugins_version"
        classpath "org.jetbrains.kotlin:kotlin-noarg:$kotlin_version"
    }
}

plugins {
    id "com.jfrog.artifactory" version "4.16.1"
}

allprojects {
    version accounts_release_version
    group accounts_release_group

    configurations.all {
        resolutionStrategy {
            // Force dependencies to use the same version of Kotlin
            force "org.jetbrains.kotlin:kotlin-stdlib-jdk7:$kotlin_version"
            force "org.jetbrains.kotlin:kotlin-stdlib-jdk8:$kotlin_version"
            force "org.jetbrains.kotlin:kotlin-stdlib-jre8:$kotlin_version"
            force "org.jetbrains.kotlin:kotlin-stdlib-jre7:$kotlin_version"
            force "org.jetbrains.kotlin:kotlin-reflect:$kotlin_version"
        }
    }
}

subprojects {
    buildscript {
        repositories {
            mavenCentral()
           // as last resort, check our backup of now defunc JCenter repo
           maven { url "${publicArtifactURL}/jcenter-backup" }
        }
    }

    apply plugin: 'kotlin'

    repositories {
        mavenLocal()
        mavenCentral()
        maven { url "${publicArtifactURL}/corda-dev" }
        maven { url "${publicArtifactURL}/corda-releases" }
        maven { url "${publicArtifactURL}/corda-dependencies" }
        maven { url "${publicArtifactURL}/corda-lib" }
        maven { url "${publicArtifactURL}/corda-lib-dev" }
        maven { url "https://repo.gradle.org/gradle/libs-releases-local" }
        maven { url 'https://jitpack.io' }
        // as last resort, check our backup of now defunc JCenter repo
        maven { url "${publicArtifactURL}/jcenter-backup" }
    }

    tasks.withType(org.jetbrains.kotlin.gradle.tasks.KotlinCompile).all {
        kotlinOptions {
            languageVersion = "1.2"
            apiVersion = "1.2"
            jvmTarget = "1.8"
            javaParameters = true   // Useful for reflection.
        }
    }


    tasks.withType(Test).all {
        minHeapSize = "128m"
        maxHeapSize = "4096m"
    }
}

// don't publish accounts-contracts unless explicitly requested.
//def publishProjects = [project(":contracts"), project(":workflows")]
def publishProjects = [project(":workflows")]


configure(publishProjects) { subproject ->
    apply plugin: 'maven-publish'
    apply plugin: 'com.jfrog.artifactory'

    task sourceJar(type: Jar, dependsOn: subproject.classes) {
        classifier = 'sources'
        from sourceSets.main.allSource
    }

    task javadocJar(type: Jar, dependsOn: subproject.javadoc) {
        classifier = 'javadoc'
        from javadoc.destinationDir
    }

    task install(dependsOn: 'publishToMavenLocal')

    publishing {
        publications {
            create(subproject.name, MavenPublication) {
                from components.java

                groupId subproject.group
                artifactId "accounts-${subproject.name}"
                artifact tasks.sourceJar
                artifact tasks.javadocJar

                pom {
                    description = subproject.description
                }
            }
        }
    }
}

artifactory {
    publish {
        contextUrl = 'https://software.r3.com/artifactory'
        repository {
            repoKey = project.hasProperty("publishRepo") ? project.property("publishRepo") : ""
            username = System.getenv('ARTIFACTORY_USERNAME') ?: System.getProperty('corda.artifactory.username')
            password = System.getenv('ARTIFACTORY_PASSWORD') ?: System.getProperty('corda.artifactory.password')
        }

        defaults {
            if (publishProjects.contains(project)) {
                publications(project.name)
            }
        }
    }
}


wrapper {
    gradleVersion = "5.6"
    distributionType = Wrapper.DistributionType.ALL
}