-
Notifications
You must be signed in to change notification settings - Fork 20
/
Copy patheldev-ecukes.el
163 lines (141 loc) · 8.2 KB
/
eldev-ecukes.el
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
;;; eldev-ecukes.el --- Elisp development tool -*- lexical-binding: t -*-
;;; Copyright (C) 2021-2024 Paul Pogonyshev
;; This program is free software; you can redistribute it and/or
;; modify it under the terms of the GNU General Public License as
;; published by the Free Software Foundation, either version 3 of
;; the License, or (at your option) any later version.
;; This program is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
;; GNU General Public License for more details.
;;
;; You should have received a copy of the GNU General Public License
;; along with this program. If not, see https://www.gnu.org/licenses.
;;; Code:
(require 'eldev)
(defvar ecukes-verbose)
(defvar ecukes-only-failing)
(defvar ecukes-failing-scenarios-file)
(defvar ecukes-patterns)
(defvar ecukes-anti-patterns)
(defvar ecukes-include-tags)
(defvar ecukes-exclude-tags)
(defvar ecukes-stats-scenarios)
(defvar ecukes-stats-scenarios-passed)
(defvar ecukes-stats-scenarios-failed)
(declare-function ecukes-load "ecukes")
(declare-function ecukes-reporter-use "ecukes")
(declare-function ecukes-run "ecukes")
(defvar eldev--ecukes-backtraces)
(defvar eldev--ecukes-current-step)
(defvar eldev--test-ecukes-initialized nil)
(defun eldev--test-init-ecukes ()
;; Apparently these variables are touched only by `ecukes-cli', which is not included,
;; but we add a safeguard in case Ecukes is changed later.
(unless eldev--test-ecukes-initialized
(let ((debugger debugger)
(debug-on-error debug-on-error))
(eldev--require-external-feature 'ecukes))
(ecukes-load)
(setf eldev--test-ecukes-initialized t)))
(defun eldev-test-ecukes-preprocess-selectors (selectors)
"Convert SELECTORS to Ecukes patterns and tags."
(dolist (selector selectors)
(let ((pattern (if (string-prefix-p "~" selector) (substring selector 1) selector)))
(unless (or (string-prefix-p "@" pattern) (eldev-valid-regexp-p pattern))
(signal 'eldev-error `("Non-tag selector/pattern `%s' is not a valid regular expression" ,selector)))))
selectors)
(defmacro eldev--test-ecukes-split-selectors (selectors &rest body)
(declare (indent 1))
`(let (ecukes-only-failing
(ecukes-failing-scenarios-file (expand-file-name "failing-scenarios.ecukes" (eldev-cache-dir t t)))
ecukes-patterns
ecukes-anti-patterns
ecukes-include-tags
ecukes-exclude-tags)
(dolist (selector (reverse ,selectors))
(if (member selector '(":failed" ":failing"))
(setf ecukes-only-failing t)
(let ((negated (string-prefix-p "~" selector)))
(when negated
(setf selector (substring selector 1)))
(let ((tag (string-prefix-p "@" selector)))
(when tag
(setf selector (substring selector 1)))
(push selector (if tag
(if negated ecukes-exclude-tags ecukes-include-tags)
(if negated ecukes-anti-patterns ecukes-patterns)))))))
,@body))
(defun eldev-run-ecukes-tests (feature-files selectors &optional environment)
"Run Ecukes tests according to given SELECTORS (patterns)."
(eldev--test-init-ecukes)
(eldev-bind-from-environment environment (ecukes-verbose)
(ecukes-reporter-use "dot")
(eldev--test-ecukes-split-selectors selectors
(let* (skip-the-rest
have-skipped-something
(maybe-skip (lambda ()
(when skip-the-rest
(unless have-skipped-something
(eldev-warn "Stopping early because of the failed scenario%s" (if (> ecukes-stats-scenarios-failed 1) "s" "")))
(setf have-skipped-something t)))))
(eldev-advised ('ecukes-run-feature :around (lambda (original &rest args)
(unless (funcall maybe-skip)
(apply original args))))
(eldev-advised ('ecukes-run-scenario :around (lambda (original &rest args)
(unless (funcall maybe-skip)
(let ((failures-before ecukes-stats-scenarios-failed))
(apply original args)
(when (and eldev-test-stop-on-unexpected
(> ecukes-stats-scenarios-failed failures-before)
(<= (setf eldev-test-stop-on-unexpected (1- eldev-test-stop-on-unexpected)) 0))
(setf skip-the-rest t))))))
;; Inject profiling support if wanted.
(eldev-advised ('ecukes-run-steps :around (when eldev--effective-profile-mode
(lambda (original &rest args)
(eldev-backtrace-notch 'eldev
(eldev-profile-body
(apply original args))))))
(if eldev-test-print-backtraces
(let ((eldev--ecukes-backtraces (make-hash-table :test #'eq)))
(eldev-advised ('ecukes-run-step :around #'eldev--ecukes-run-step)
(eldev-advised ('ecukes-reporter-print-step :after (lambda (step)
(let ((backtrace (gethash step eldev--ecukes-backtraces)))
(when backtrace
(eldev-output "%s" backtrace)))))
(ecukes-run feature-files))))
;; Not trying to highlight the summary, Ecukes already does that itself.
(ecukes-run feature-files)))))
(setf eldev-test-num-passed (+ eldev-test-num-passed ecukes-stats-scenarios-passed)
eldev-test-num-failed (+ eldev-test-num-failed ecukes-stats-scenarios-failed))
(when (> ecukes-stats-scenarios-failed 0)
(signal 'eldev-error `("%s failed" ,(eldev-message-plural ecukes-stats-scenarios-failed "Ecukes scenario"))))))))
(defun eldev--ecukes-run-step (original step &rest args)
(let ((eldev--ecukes-current-step step)
(debug-on-error t)
(debugger #'eldev--ecukes-backtrace-collector))
(apply original step args)))
(defun eldev--ecukes-backtrace-collector (&rest args)
(when (eq (car args) 'error)
(let* ((frames (cdr (eldev-backtrace-frames #'eldev--ecukes-backtrace-collector)))
(scan (reverse frames))
;; We are going to indent it.
(eldev-backtrace-style (if (integerp eldev-backtrace-style) (- eldev-backtrace-style 4) eldev-backtrace-style)))
(while scan
(let ((frame (pop scan)))
(when (eq (eldev-backtrace-frame-function frame) #'eldev--ecukes-run-step)
;; Heuristic: if not byte-compiled, drop `let' frame (see above).
(when (and (not (byte-code-function-p #'eldev--ecukes-run-step)) (eq (eldev-backtrace-frame-function (car scan)) 'let))
(setf scan (cdr scan)))
;; Heuristic: drop a few more uninteresting frames.
(when (and (eq (eldev-backtrace-frame-function (nth 0 scan)) 'apply)
(byte-code-function-p (eldev-backtrace-frame-function (nth 1 scan)))
(eq (eldev-backtrace-frame-function (nth 2 scan)) 'apply)
(eq (car-safe (eldev-backtrace-frame-function (nth 3 scan))) 'lambda))
(setf scan (nthcdr 4 scan)))
(setf frames (nreverse scan)
scan nil))))
(puthash eldev--ecukes-current-step (replace-regexp-in-string "^" " " (eldev-backtrace-to-string frames) t t)
eldev--ecukes-backtraces))))
(provide 'eldev-ecukes)
;;; eldev-ecukes.el ends here