CHNROSNB.SIF

***************************
* SET UP THE INITIAL DATA *
***************************

NAME          CHNROSNB

*   Problem :
*   --------
*   The chained Rosenbrock function (Toint)

*   Source:
*   Ph.L. Toint,
*   "Some numerical results using a sparse matrix updating formula in
*   unconstrained optimization",
*   Mathematics of Computation, vol. 32(114), pp. 839-852, 1978.

*   See also Buckley#46 (n = 25) (p. 45).
*   SIF input: Ph. Toint, Dec 1989.

*   classification SUR2-AN-V-0

*   Number of variables ( at most 50)

*IE N                   10             $-PARAMETER     original value
*IE N                   25             $-PARAMETER
 IE N                   50             $-PARAMETER

*   Problem data

 RE ALPH1               1.25
 RE ALPH2               1.40
 RE ALPH3               2.40
 RE ALPH4               1.40
 RE ALPH5               1.75
 RE ALPH6               1.20
 RE ALPH7               2.25
 RE ALPH8               1.20
 RE ALPH9               1.00
 RE ALPH10              1.10
 RE ALPH11              1.50
 RE ALPH12              1.60
 RE ALPH13              1.25
 RE ALPH14              1.25
 RE ALPH15              1.20
 RE ALPH16              1.20
 RE ALPH17              1.40
 RE ALPH18              0.50
 RE ALPH19              0.50
 RE ALPH20              1.25
 RE ALPH21              1.80
 RE ALPH22              0.75
 RE ALPH23              1.25
 RE ALPH24              1.40
 RE ALPH25              1.60
 RE ALPH26              2.00
 RE ALPH27              1.00
 RE ALPH28              1.60
 RE ALPH29              1.25
 RE ALPH30              2.75
 RE ALPH31              1.25
 RE ALPH32              1.25
 RE ALPH33              1.25
 RE ALPH34              3.00
 RE ALPH35              1.50
 RE ALPH36              2.00
 RE ALPH37              1.25
 RE ALPH38              1.40
 RE ALPH39              1.80
 RE ALPH40              1.50
 RE ALPH41              2.20
 RE ALPH42              1.40
 RE ALPH43              1.50
 RE ALPH44              1.25
 RE ALPH45              2.00
 RE ALPH46              1.50
 RE ALPH47              1.25
 RE ALPH48              1.40
 RE ALPH49              0.60
 RE ALPH50              1.50

*   other parameter definitions

 IE 1                   1
 IE 2                   2

VARIABLES

 DO I         1                        N
 X  X(I)
 ND

GROUPS

 DO I         2                        N
 IA I-1       I         -1
 XN SQ(I)     X(I-1)    1.0
 A* AI2       ALPH(I)                  ALPH(I)
 RM 16AI2     AI2       16.0
 RD SCL       16AI2     1.0
 ZN SQ(I)     'SCALE'                  SCL
 XN B(I)      X(I)      1.0
 ND

CONSTANTS

 DO I         2                        N
 X  CHNROSNB  B(I)      1.0
 ND

BOUNDS

 FR CHNROSNB  'DEFAULT'

START POINT

 XV CHNROSMB  'DEFAULT' -1.0

ELEMENT TYPE

 EV ETYPE     V1

ELEMENT USES

 XT 'DEFAULT' ETYPE

 DO I         2                        N
 ZV ELA(I)    V1                       X(I)
 ND

GROUP TYPE

 GV L2        GVAR

GROUP USES

 XT 'DEFAULT' L2

 DO I         2                        N
 XE SQ(I)     ELA(I)
 ND

OBJECT BOUND

 LO CHNROSNB            0.0

*   Solution

*LO SOLTN               0.0

ENDATA

***********************
* SET UP THE FUNCTION *
* AND RANGE ROUTINES  *
***********************

ELEMENTS      CHNROSNB

INDIVIDUALS

 T  ETYPE
 F                      - V1 ** 2
 G  V1                  - 2.0 * V1
 H  V1        V1        - 2.0

ENDATA

*********************
* SET UP THE GROUPS *
* ROUTINE           *
*********************

GROUPS        CHNROSNB

INDIVIDUALS

 T  L2

 F                      GVAR * GVAR
 G                      GVAR + GVAR
 H                      2.0

ENDATA