bubble-sort.lala

structure int-array {
    length: int
    values: [int]
}

function read-int-array(): int-array {
    var array: int-array = int-array(0, [])

    print 'Enter array length:'
    array.length = read int

    print 'Enter array elements:'
    array.values = [0] * array.length

    var i: int = 0
    while i < array.length {
        array.values[i] = read int
        i = i + 1
    }

    return array
}

function int-array-to-string(var array: int-array): string {
    var str: string = '['
    
    var i: int = 0
    while i < array.length {
        str = str + array.values[i]: string
        if i < array.length - 1
            str = str + ' '
        i = i + 1
    }

    str = str + ']'

    return str
}

function bubble-sort-int-array(var array: int-array): void {
    var n: int = array.length

    var did-swap: bool = false
    do {
        did-swap = false

        var i: int = 1
        while i < n {
            if array.values[i - 1] > array.values[i] {
                var temp: int = array.values[i - 1]
                array.values[i - 1] = array.values[i]
                array.values[i] = temp
                did-swap = true
            }
            i = i + 1
        }
        n = n - 1
    } while did-swap
}


print 'Sorts an array using bubble sort.'

var array: int-array = read-int-array()
print 'Before sort: ' + int-array-to-string(array)

bubble-sort-int-array(array)
print 'After  sort: ' + int-array-to-string(array)