while.y

%language "c++"
%locations
%define api.value.type variant

%code top {
#include "implementation.hh"
#include <list>
}

%code provides {
int yylex(yy::parser::semantic_type* yylval, yy::parser::location_type* yylloc);
}

%token PRG
%token BEG
%token END
%token BOO
%token NAT
%token REA
%token WRI
%token IF
%token THE
%token ELS
%token EIF
%token WHI
%token DO
%token DON
%token TRU
%token FAL
%token ASN
%token OP
%token CL
%token COL
%token QUE
%token FOR
%token TO
%token COM
%token <std::string> ID
%token <std::string> NUM

%left OR
%left AND
%left EQ
%left LS GR LSE GRE
%left ADD SUB
%left MUL DIV MOD
%precedence NOT

%type <expression*> expression
%type <instruction*> command
%type <std::list<instruction*>* > commands
%type <std::list<std::string>* > ids
%type <std::list<expression*>* > expressions

%%

start:
    PRG ID declarations BEG commands END
    {
        type_check_commands($5);
        if(current_mode == compiler) {
            generate_code($5);
        } else {
            execute_commands($5);
        }
        delete_commands($5);
    }
;

declarations:
    // empty
|
    declarations declaration
;

declaration:
    BOO ID
    {
        symbol(@1.begin.line, $2, boolean).declare();
    }
|
    NAT ID
    {
        symbol(@1.begin.line, $2, natural).declare();
    }
;

commands:
    // empty
    {
        $$ = new std::list<instruction*>();
    }
|
    commands command
    {
        $1->push_back($2);
        $$ = $1;
    }
;

ids:
    ID
    {
         $$ = new std::list<std::string>();
         $$->push_back($1);
    }
|
    ids COM ID
    {
          $1->push_back($3);
          $$ = $1;
    }
;

expressions:
    expression
    {
         $$ = new std::list<expression*>();
         $$->push_back($1);
    }
|
    expressions COM expression
    {
          $1->push_back($3);
          $$ = $1;
    }
;

command:
    REA OP ID CL
    {
        $$ = new read_instruction(@1.begin.line, $3);
    }
|
    WRI OP expression CL
    {
        $$ = new write_instruction(@1.begin.line, $3);
    }
|
    ids ASN expressions
    {
        $$ = new assign_instructions(@2.begin.line, $1, $3);
    }
|
    IF expression THE commands EIF
    {
        $$ = new if_instruction(@1.begin.line, $2, $4, 0);
    }
|
    IF expression THE commands ELS commands EIF
    {
        $$ = new if_instruction(@1.begin.line, $2, $4, $6);
    }
|
    WHI expression DO commands DON
    {
        $$ = new while_instruction(@1.begin.line, $2, $4);
    }
|
    FOR ID ASN expression TO expression DO commands DON
    {
        $$ = new for_instruction(@1.begin.line, $2, $4, $6, $8);
    }
;

expression:
    NUM
    {
        $$ = new number_expression($1);
    }
|
    TRU
    {
        $$ = new boolean_expression(true);
    }
|
    FAL
    {
        $$ = new boolean_expression(false);
    }
|
    ID
    {
        $$ = new id_expression(@1.begin.line, $1);
    }
|
    OP expression QUE expression COL expression CL
    {
        $$ = new trinaryop_expression(@2.begin.line, $2, $4, $6);
    }
|
    expression ADD expression
    {
        $$ = new binop_expression(@2.begin.line, "+", $1, $3);
    }
|
    expression SUB expression
    {
        $$ = new binop_expression(@2.begin.line, "-", $1, $3);
    }
|
    expression MUL expression
    {
        $$ = new binop_expression(@2.begin.line, "*", $1, $3);
    }
|
    expression DIV expression
    {
        $$ = new binop_expression(@2.begin.line, "/", $1, $3);
    }
|
    expression MOD expression
    {
        $$ = new binop_expression(@2.begin.line, "%", $1, $3);
    }
|
    expression LS expression
    {
        $$ = new binop_expression(@2.begin.line, "<", $1, $3);
    }
|
    expression GR expression
    {
        $$ = new binop_expression(@2.begin.line, ">", $1, $3);
    }
|
    expression LSE expression
    {
        $$ = new binop_expression(@2.begin.line, "<=", $1, $3);
    }
|
    expression GRE expression
    {
        $$ = new binop_expression(@2.begin.line, ">=", $1, $3);
    }
|
    expression AND expression
    {
        $$ = new binop_expression(@2.begin.line, "and", $1, $3);
    }
|
    expression OR expression
    {
        $$ = new binop_expression(@2.begin.line, "or", $1, $3);
    }
|
    expression EQ expression
    {
        $$ = new binop_expression(@2.begin.line, "=", $1, $3);
    }
|
    NOT expression
    {
        $$ = new not_expression(@1.begin.line, "not", $2);
    }
|
    OP expression CL
    {
        $$ = $2;
    }
;

%%