Add SDL3

README.md

@@ -5,13 +5,14 @@ A personal collection of unusual things
   * substituter: `https://attic.eleonora.gay/default`
   * public key:  `default:3FYh8sZV8gWa7Jc5jlP7gZFK7pt3kaHRiV70ySaQ42g=`
 
-## 51 Packages
+## 52 Packages
 
 | Name | Version | Description | Homepage |
 |------|---------|-------------|----------|
 |`9mount`|`1.3`|A set of SUID tools for mounting 9p filesystems via v9fs|https://sqweek.net/code/9mount|
 |`CatgirlDownloader`|`0.2.7`|A GTK4 application that downloads images of catgirls based on https://nekos.moe|https://github.com/NyarchLinux/CatgirlDownloader|
 |`ImageColorizer`|`2021-10-31`|Make any wallpaper fit any terminal colorscheme|https://github.com/kiddae/ImageColorizer|
+|`SDL3`|`3.1.6`|Simple Directmedia Layer|https://libsdl.org|
 |`agregore`|`2.4.0`|A minimal browser for the distributed web|https://github.com/AgregoreWeb/agregore-browser|
 |`argtable2`|`2.13`|An ANSI C command line parser|https://argtable.sourceforge.io|
 |`avh`|`n/a`|AvH video storage|https://github.com/42LoCo42/avh|

packages/SDL3.nix

@@ -0,0 +1,64 @@
+pkgs: pkgs.stdenv.mkDerivation rec {
+  pname = "SDL3";
+  version = "3.1.6";
+
+  src = pkgs.fetchFromGitHub {
+    owner = "libsdl-org";
+    repo = "SDL";
+    rev = "preview-${version}";
+    hash = "sha256-MItZt5QeEz13BeCoLyXVUbk10ZHNyubq7dztjDq4nt4=";
+  };
+
+  nativeBuildInputs = with pkgs; [
+    cmake
+    ninja
+    pkg-config
+    wayland-scanner
+  ];
+
+  buildInputs = (with pkgs; [
+    # libffi
+    # libsysprof-capture
+    # pcre2
+    # util-linux
+
+    alsa-lib # alsa.pc
+    dbus # dbus-1.pc
+    ibus # ibus-1.0.pc
+    kdePackages.wayland # wayland-client.pc wayland-egl.pc wayland-cursor.pc
+    libGL # egl.pc GL/gl.h GL/glext.h
+    libdecor # libdecor-0.pc
+    libdrm # libdrm.pc
+    libjack2 # jack.pc
+    libpulseaudio # libpulse.pc
+    libunwind # libunwind.pc libunwind-generic.pc
+    libusb1 # libusb-1.0.pc
+    libxkbcommon # xkbcommon.pc
+    mesa # gbm.pc
+    pipewire # libpipewire-0.3pc
+    sndio # sndio.pc
+  ]) ++ (with pkgs.xorg; [
+    libX11 # x11.pc
+    libXScrnSaver # xscrnsaver.pc
+    libXcursor # xcursor.pc
+    libXext # xext.pc
+    libXfixes # xfixes.pc
+    libXi # xi.pc
+    libXrandr # xrandr.pc
+    libXrender # xrender.pc
+  ]);
+
+  postFixup =
+    let rpath = pkgs.lib.makeLibraryPath buildInputs; in ''
+      for lib in $out/lib/*.so*; do
+        if [ ! -L "$lib" ]; then
+          patchelf --add-rpath "${rpath}" "$lib"
+        fi
+      done
+    '';
+
+  meta = {
+    description = "Simple Directmedia Layer";
+    homepage = "https://libsdl.org";
+  };
+}