feat: avoid multiple applications #2

CMakeLists.txt

@@ -20,11 +20,14 @@ add_executable(ZJUConnectForWindows WIN32
         mainwindow.h
         resource.qrc)
 
+add_subdirectory(singleapplication)
+
 target_link_libraries(ZJUConnectForWindows
         Qt::Core
         Qt::Gui
         Qt::Widgets
         Qt::Network
+        SingleApplication::SingleApplication
         )
 
 set(DEBUG_SUFFIX)

main.cpp

@@ -1,10 +1,12 @@
 #include <QApplication>
 
+#include "SingleApplication"
+
 #include "mainwindow.h"
 
 int main(int argc, char *argv[])
 {
-    QApplication app(argc, argv);
+    SingleApplication app(argc, argv);
     QApplication::setApplicationName("ZJU Connect for Windows");
     QApplication::setApplicationVersion("0.12");
 

singleapplication/CMakeLists.txt

@@ -0,0 +1,83 @@
+cmake_minimum_required(VERSION 3.12.0)
+
+project(SingleApplication LANGUAGES CXX DESCRIPTION "Replacement for QtSingleApplication")
+
+set(CMAKE_AUTOMOC ON)
+
+add_library(${PROJECT_NAME} STATIC
+    singleapplication.cpp
+    singleapplication_p.cpp
+)
+add_library(${PROJECT_NAME}::${PROJECT_NAME} ALIAS ${PROJECT_NAME})
+
+if(NOT QT_DEFAULT_MAJOR_VERSION)
+    set(QT_DEFAULT_MAJOR_VERSION 5 CACHE STRING "Qt version to use (5 or 6), defaults to 5")
+endif()
+
+# Find dependencies
+set(QT_COMPONENTS Core Network)
+set(QT_LIBRARIES Qt${QT_DEFAULT_MAJOR_VERSION}::Core Qt${QT_DEFAULT_MAJOR_VERSION}::Network)
+
+if(QAPPLICATION_CLASS STREQUAL QApplication)
+    list(APPEND QT_COMPONENTS Widgets)
+    list(APPEND QT_LIBRARIES Qt${QT_DEFAULT_MAJOR_VERSION}::Widgets)
+elseif(QAPPLICATION_CLASS STREQUAL QGuiApplication)
+    list(APPEND QT_COMPONENTS Gui)
+    list(APPEND QT_LIBRARIES Qt${QT_DEFAULT_MAJOR_VERSION}::Gui)
+else()
+    set(QAPPLICATION_CLASS QCoreApplication)
+endif()
+
+find_package(Qt${QT_DEFAULT_MAJOR_VERSION} COMPONENTS ${QT_COMPONENTS} REQUIRED)
+
+option(SINGLEAPPLICATION_DOCUMENTATION "Generate Doxygen documentation" OFF)
+if(SINGLEAPPLICATION_DOCUMENTATION)
+    find_package(Doxygen)
+endif()
+
+target_link_libraries(${PROJECT_NAME} PUBLIC ${QT_LIBRARIES})
+
+if(WIN32)
+    target_link_libraries(${PROJECT_NAME} PRIVATE advapi32)
+endif()
+
+target_compile_definitions(${PROJECT_NAME} PUBLIC QAPPLICATION_CLASS=${QAPPLICATION_CLASS})
+target_include_directories(${PROJECT_NAME} PUBLIC ${CMAKE_CURRENT_SOURCE_DIR})
+target_compile_definitions(${PROJECT_NAME} PRIVATE
+    QT_NO_CAST_TO_ASCII
+    QT_NO_CAST_FROM_ASCII
+    QT_NO_URL_CAST_FROM_STRING
+    QT_NO_CAST_FROM_BYTEARRAY
+    QT_USE_QSTRINGBUILDER
+    QT_NO_NARROWING_CONVERSIONS_IN_CONNECT
+    QT_NO_KEYWORDS
+    QT_NO_FOREACH
+)
+
+if(DOXYGEN_FOUND)
+    # Doxygen theme
+    include(FetchContent)
+    FetchContent_Declare(DoxygenAwesome
+        GIT_REPOSITORY https://github.com/jothepro/doxygen-awesome-css
+        GIT_TAG 4cd62308d825fe0396d2f66ffbab45d0e247724c # 2.0.3
+    )
+    FetchContent_MakeAvailable(DoxygenAwesome)
+    FetchContent_GetProperties(DoxygenAwesome SOURCE_DIR DoxygenAwesome_SOURCE_DIR)
+
+    set(DOXYGEN_USE_MDFILE_AS_MAINPAGE README.md)
+    set(DOXYGEN_GENERATE_TREEVIEW YES)
+    set(DOXYGEN_HTML_HEADER ${DoxygenAwesome_SOURCE_DIR}/doxygen-custom/header.html)
+    set(DOXYGEN_HTML_EXTRA_STYLESHEET ${DoxygenAwesome_SOURCE_DIR}/doxygen-awesome.css)
+    set(DOXYGEN_HTML_EXTRA_FILES
+        ${DoxygenAwesome_SOURCE_DIR}/doxygen-awesome-fragment-copy-button.js
+        ${DoxygenAwesome_SOURCE_DIR}/doxygen-awesome-paragraph-link.js
+        ${DoxygenAwesome_SOURCE_DIR}/doxygen-awesome-darkmode-toggle.js
+    )
+
+    doxygen_add_docs(${PROJECT_NAME}Documentation
+        singleapplication.h
+        CHANGELOG.md
+        Windows.md
+        README.md
+    )
+endif()

singleapplication/LICENSE

@@ -0,0 +1,24 @@
+The MIT License (MIT)
+
+Copyright (c) Itay Grudev 2015 - 2020
+
+Permission is hereby granted, free of charge, to any person obtaining a copy
+of this software and associated documentation files (the "Software"), to deal
+in the Software without restriction, including without limitation the rights
+to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
+copies of the Software, and to permit persons to whom the Software is
+furnished to do so, subject to the following conditions:
+
+The above copyright notice and this permission notice shall be included in
+all copies or substantial portions of the Software.
+
+THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
+IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
+FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
+AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
+LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
+OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN
+THE SOFTWARE.
+
+Note: Some of the examples include code not distributed under the terms of the
+MIT License.

singleapplication/SingleApplication

@@ -0,0 +1 @@
+#include "singleapplication.h"